media-sound/linuxsampler: bump to 2.2.0

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 81 insertions, 3 deletions

diff --git a/media-sound/linuxsampler/Manifest b/media-sound/linuxsampler/Manifest
index 8bec786238e3..a65394301109 100644
--- a/media-sound/linuxsampler/Manifest
+++ b/media-sound/linuxsampler/Manifest
@@ -1 +1,2 @@
 DIST linuxsampler-2.1.1.tar.bz2 1410461 BLAKE2B dacaab33601f25954ea1a3380c8e28358d2111b664982f25ec9cac46adb99241ecfd53101ca3b23428c1a16fcef738b1e7e481b1c7eeb6d9659773f5b8856b55 SHA512 3f172efe40bbe130a2ac09f9393a46a30cc327a6754a80fdb36e65276518ec82befa2075acc567ccd99c22d9859c1a65f58ff2ad7af70cd9e4649ae14fd5357c
+DIST linuxsampler-2.2.0.tar.bz2 1507276 BLAKE2B 9650938d0aace876e817884121b824713dd2f747505344d7895e7d99da62f2214fb4c4bf43c398f4e486202e23e7a57288e19734e8c565a917d823169deb717a SHA512 9015bb8d3af125e13c5c2ef3ae2d3987f7b7dda72e238cff25e622a3291019f5e392195dd27e7e783c70d877d9b267915fc443369eb17117e5eb7c54b8496c68
diff --git a/media-sound/linuxsampler/linuxsampler-2.2.0.ebuild b/media-sound/linuxsampler/linuxsampler-2.2.0.ebuild
new file mode 100644
index 000000000000..db469f65a3ab
--- /dev/null
+++ b/media-sound/linuxsampler/linuxsampler-2.2.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="Software audio sampler engine with professional grade features"
+HOMEPAGE="https://www.linuxsampler.org/"
+SRC_URI="https://download.linuxsampler.org/packages/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa doc jack lv2 sf2 sqlite"
+REQUIRED_USE="|| ( alsa jack )"
+
+RDEPEND="
+	media-libs/libgig
+	media-libs/libsndfile[-minimal]
+	alsa? ( media-libs/alsa-lib )
+	jack? ( virtual/jack )
+	lv2? ( media-libs/lv2 )
+	sqlite? ( dev-db/sqlite )
+"
+DEPEND="${RDEPEND}
+	media-libs/dssi
+	media-libs/ladspa-sdk
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.0.0-nptl-hardened.patch"
+	"${FILESDIR}/${PN}-2.0.0-lv2-automagic.patch"
+	"${FILESDIR}/${PN}-2.1.1-fix-yyterror-not-declared.patch"
+)
+
+DOCS=( AUTHORS ChangeLog NEWS README )
+
+src_prepare() {
+	default
+	# Force regeneration of the file to let it build with all bison
+	# versions, bug #556204
+	rm src/network/lscpparser.cpp || die
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-arts-driver
+		--disable-static
+		$(use_enable alsa alsa-driver)
+		$(use_enable jack jack-driver)
+		$(use_enable lv2)
+		$(use_enable sqlite instruments-db)
+		$(use_enable sf2 sf2-engine)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake
+	use doc && emake docs
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( doc/html/. )
+	default
+	find "${D}" -name '*.la' -delete || die
+
+	# lscp files conflict with nilfs-utils, bug #556330
+	mv "${D}/usr/bin/lscp" "${D}/usr/bin/lscp-${PN}" || die
+	mv "${D}/usr/share/man/man1/lscp.1" "${D}/usr/share/man/man1/lscp-${PN}.1" || die
+}
diff --git a/media-sound/linuxsampler/linuxsampler-9999.ebuild b/media-sound/linuxsampler/linuxsampler-9999.ebuild
index bd097fd3cce7..d33e3b81f2f0 100644
--- a/media-sound/linuxsampler/linuxsampler-9999.ebuild
+++ b/media-sound/linuxsampler/linuxsampler-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2019 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -16,12 +16,12 @@ IUSE="alsa doc jack lv2 sf2 sqlite"
 REQUIRED_USE="|| ( alsa jack )"
 
 RDEPEND="
-	>=media-libs/libgig-4.2.0
+	media-libs/libgig
 	media-libs/libsndfile[-minimal]
 	alsa? ( media-libs/alsa-lib )
 	jack? ( virtual/jack )
 	lv2? ( media-libs/lv2 )
-	sqlite? ( >=dev-db/sqlite-3.3 )
+	sqlite? ( dev-db/sqlite )
 "
 DEPEND="${RDEPEND}
 	media-libs/dssi