net-misc/remmina: bump to 1.4.13

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Ben Kohler <bkohler@gentoo.org>

2 files changed, 103 insertions, 0 deletions

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index 47c93e22f89c..6c445d2a2035 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,2 +1,3 @@
 DIST Remmina-v1.4.11.tar.gz 2176470 BLAKE2B 1d0923e520716f1cf0d1d153dab6eb3d22ef2fb53b8b51f8cd65672c9a92e7bbcc254915a0a7e269dc478aa2d39a15ab388056dc8c435997c2f0a8f257e589bd SHA512 9b26002451d297e49c63e6ce39a51d434eb18f78b3c2ef8770e2ded319ead4478a4f1ad4d4fefa19ddf3390d740bc34ce27d0c0eb0c24e39a2d792f6f66079b5
 DIST Remmina-v1.4.12.tar.gz 2338965 BLAKE2B 86ec07a2c5ff0957cc3d855a4cc86c9675aa474110d7d40d202817f01c4d5815c008a5f0f78802e9b3ef14b3590d58ccbb124e2b6c6f0b14ea8c8592a4d8bd50 SHA512 7ae8031ff64c113b0ed792c6ba56c42918ccce5a30fe0255f730ef7a5a712dc500495e591598fd6cc553c09c6d5a2457e33f4dc1019403e89b25cc02e491515d
+DIST Remmina-v1.4.13.tar.gz 2519879 BLAKE2B ff2410ffbdea4509866b41e47eaa8caafb7f45091047eff9a830590b7a04c25cbbdec5788ccf9f35afdee613722e74e7595b73b4c3c8eea2fa3ffb4e09411d99 SHA512 cf82dc90f021635bcde906a73a2ad59087fe7cbe1bdd69a828ffc1e04ea0cc1bfa23386b70c36df85ae41dfa17f2d4379bedff29c03d9838c6ac18347e06b6dc
diff --git a/net-misc/remmina/remmina-1.4.13.ebuild b/net-misc/remmina/remmina-1.4.13.ebuild
new file mode 100644
index 000000000000..3ce94b27c5dc
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.13.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake optfeature xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC, XDMCP and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/v${PV}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="appindicator crypt cups examples gnome-keyring kwallet libressl nls spice ssh rdp telemetry telepathy vnc webkit zeroconf"
+
+DEPEND="
+	app-emulation/spice-protocol
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libsodium:=
+	net-libs/libsoup
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libxkbfile
+	appindicator? ( dev-libs/libappindicator:3 )
+	crypt? ( dev-libs/libgcrypt:0= )
+	rdp? ( >=net-misc/freerdp-2.0.0_rc4_p1129[X]
+		<net-misc/freerdp-3[X]
+		cups? ( net-print/cups:= ) )
+	gnome-keyring? ( app-crypt/libsecret )
+	kwallet? ( kde-frameworks/kwallet )
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	telepathy? ( net-libs/telepathy-glib )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4 )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+BDEPEND="
+	dev-util/intltool
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_APPINDICATOR=$(usex appindicator)
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_LIBSECRET=$(usex gnome-keyring)
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_FREERDP3=OFF
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_TELEPATHY=$(usex telepathy)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_NEWS=$(usex telemetry)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+		# when this feature is stable, add python eclass usage to optionally enable
+		-DWITH_PYTHON=OFF
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "To get additional features, some optional runtime dependencies"
+	elog "may be installed:"
+	elog ""
+	optfeature "encrypted VNC connections" net-libs/libvncserver[gcrypt]
+	optfeature "XDMCP support" x11-base/xorg-server[xephyr]
+}