net-wireless/gr-osmosdr: add 0.2.5

Move to using new upstream location (still original upstream)
Github mirror is not currently being updated, email sent to upstream,
removing for now
Signed-off-by: Rick Farina <zerochaos@gentoo.org>

4 files changed, 91 insertions, 10 deletions

diff --git a/net-wireless/gr-osmosdr/Manifest b/net-wireless/gr-osmosdr/Manifest
index 453f9b2916af..84db96a74b50 100644
--- a/net-wireless/gr-osmosdr/Manifest
+++ b/net-wireless/gr-osmosdr/Manifest
@@ -1,2 +1,3 @@
 DIST gr-osmosdr-0.2.3_p20210128.tar.gz 257938 BLAKE2B 1bdb3b57ec6a2f942769770c34d41b4e3db5b62f8c337d724b0099f9a2fe5bdb7231bc0727dfe4bd01cd62918b4847ea2f8780208c0960bced5853c716ec6f02 SHA512 4dcb6b2c10eeb2252111ba691be179fe5b6dc9598fa7e6129a3b214ee74d43ca2d67ab5eafa73cea2abb25729c24be0592585d149e13c7285f2ce330e52a6470
 DIST gr-osmosdr-0.2.4.tar.gz 260745 BLAKE2B 6af08b2658619edbbbf398aebcd3b3262f03aa7ed9d18c31970c255f093ea60d8da8597635fdd33a267a005a375fd54b82d1405c6674ad92721c38b3e4660a16 SHA512 04b54c92e40e58b76a9e6c9c3fb419f97af2599ca2f92cb58858464722e993ebe05896ffee2592ced729521ec65857eac9fac7809567c8b6de62a0ff99f615d5
+DIST gr-osmosdr-0.2.5.tar.gz 267914 BLAKE2B cec3790513a8e050610cb4b7f928c7b1d47e5b34e372f577c7f90a929a7353e2d7a86d04b8fcde57b24cc08554c5bee7257c052263de55e0f5ba3201f19a275c SHA512 d1c126d94accbd292624022df6ff7febecb1c73c3a1a0c3e8d0e3e4d882076df5b77ad14d79966a150e2c9d889c391239b1dc831acf49cdf891a19db7f830901
diff --git a/net-wireless/gr-osmosdr/gr-osmosdr-0.2.5.ebuild b/net-wireless/gr-osmosdr/gr-osmosdr-0.2.5.ebuild
new file mode 100644
index 000000000000..9ff0faaaba65
--- /dev/null
+++ b/net-wireless/gr-osmosdr/gr-osmosdr-0.2.5.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake python-single-r1
+
+DESCRIPTION="GNU Radio source block for OsmoSDR and rtlsdr and hackrf"
+HOMEPAGE="
+	https://sdr.osmocom.org/trac/wiki/GrOsmoSDR
+	https://gitea.osmocom.org/sdr/gr-osmosdr
+"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitea.osmocom.org/sdr/gr-osmosdr.git"
+else
+	SRC_URI="https://gitea.osmocom.org/sdr/gr-osmosdr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~riscv ~x86"
+	S="${WORKDIR}/${PN}"
+fi
+
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+IUSE="airspy bladerf doc hackrf iqbalance python rtlsdr sdrplay soapy uhd xtrx"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/boost:=
+	dev-libs/log4cpp
+	net-wireless/gnuradio:0=[${PYTHON_SINGLE_USEDEP}]
+	sci-libs/volk:=
+	airspy? ( net-wireless/airspy )
+	bladerf? ( >=net-wireless/bladerf-2018.08_rc1:= )
+	hackrf? ( net-libs/libhackrf:= )
+	iqbalance? ( net-wireless/gr-iqbal:=[${PYTHON_SINGLE_USEDEP}] )
+	rtlsdr? ( >=net-wireless/rtl-sdr-0.5.4:= )
+	sdrplay? ( net-wireless/sdrplay )
+	soapy? ( net-wireless/soapysdr:= )
+	uhd? ( net-wireless/uhd:=[${PYTHON_SINGLE_USEDEP}] )
+	xtrx? ( net-wireless/libxtrx )
+	"
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+		$(python_gen_cond_dep 'dev-python/pybind11[${PYTHON_USEDEP}]')
+		doc? ( app-doc/doxygen )
+	"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.2.3_p20210128-fix-enable-python.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_DEFAULT=OFF
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+		-DENABLE_FILE=ON
+		-DENABLE_AIRSPY="$(usex airspy ON OFF)"
+		-DENABLE_BLADERF="$(usex bladerf ON OFF)"
+		-DENABLE_HACKRF="$(usex hackrf ON OFF)"
+		-DENABLE_IQBALANCE="$(usex iqbalance ON OFF)"
+		-DENABLE_PYTHON="$(usex python ON OFF)"
+		-DENABLE_RTL="$(usex rtlsdr ON OFF)"
+		-DENABLE_RTL_TCP="$(usex rtlsdr ON OFF)"
+		-DENABLE_SDRPLAY="$(usex sdrplay ON OFF)"
+		-DENABLE_NONFREE="$(usex sdrplay ON OFF)"
+		-DENABLE_SOAPY="$(usex soapy ON OFF)"
+		-DENABLE_UHD="$(usex uhd ON OFF)"
+		-DENABLE_XTRX="$(usex xtrx ON OFF)"
+		-DENABLE_DOXYGEN="$(usex doc ON OFF)"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	if use python; then
+		find "${ED}" -name '*.py[oc]' -delete || die
+		python_fix_shebang "${ED}"/usr/bin
+		python_optimize
+	fi
+	mv "${ED}/usr/share/doc/${PN}" "${ED}/usr/share/doc/${P}"
+}
diff --git a/net-wireless/gr-osmosdr/gr-osmosdr-9999.ebuild b/net-wireless/gr-osmosdr/gr-osmosdr-9999.ebuild
index c2a2986ffc9f..9ff0faaaba65 100644
--- a/net-wireless/gr-osmosdr/gr-osmosdr-9999.ebuild
+++ b/net-wireless/gr-osmosdr/gr-osmosdr-9999.ebuild
@@ -14,15 +14,11 @@ HOMEPAGE="
 
 if [[ ${PV} == 9999* ]]; then
 	inherit git-r3
-	EGIT_REPO_URI="https://github.com/osmocom/gr-osmosdr.git"
+	EGIT_REPO_URI="https://gitea.osmocom.org/sdr/gr-osmosdr.git"
 else
-	#commit
-	COMMIT="a100eb024c0210b95e4738b6efd836d48225bd03"
-	SRC_URI="https://github.com/osmocom/gr-osmosdr/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
-	S="${WORKDIR}/${PN}-${COMMIT}"
-	#release
-	#SRC_URI="https://github.com/osmocom/gr-osmosdr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI="https://gitea.osmocom.org/sdr/gr-osmosdr/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~arm ~riscv ~x86"
+	S="${WORKDIR}/${PN}"
 fi
 
 LICENSE="GPL-3"
diff --git a/net-wireless/gr-osmosdr/metadata.xml b/net-wireless/gr-osmosdr/metadata.xml
index e19fa75ed167..034011869409 100644
--- a/net-wireless/gr-osmosdr/metadata.xml
+++ b/net-wireless/gr-osmosdr/metadata.xml
@@ -16,7 +16,4 @@
 		<flag name="uhd">Build with Ettus Research USRP Hardware Driver support through <pkg>net-wireless/uhd</pkg></flag>
 		<flag name="xtrx">Build with xtrx Hardware Driver support through <pkg>net-wireless/libxtrx</pkg></flag>
 	</use>
-	<upstream>
-		<remote-id type="github">osmocom/gr-osmosdr</remote-id>
-	</upstream>
 </pkgmetadata>