sci-libs/adolc: always enable essential features

Package-Manager: Portage-2.3.31, Repoman-2.3.9

1 files changed, 56 insertions, 0 deletions

diff --git a/sci-libs/adolc/adolc-2.6.3-r1.ebuild b/sci-libs/adolc/adolc-2.6.3-r1.ebuild
new file mode 100644
index 000000000000..8e711996d79c
--- /dev/null
+++ b/sci-libs/adolc/adolc-2.6.3-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools toolchain-funcs eutils
+
+MYPN=ADOL-C
+
+DESCRIPTION="Automatic differentiation system for C/C++"
+HOMEPAGE="https://projects.coin-or.org/ADOL-C/"
+SRC_URI="http://www.coin-or.org/download/source/${MYPN}/${MYPN}-${PV}.tgz"
+
+LICENSE="|| ( EPL-1.0 GPL-2 )"
+SLOT="0/2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="+boost mpi sparse static-libs"
+
+RDEPEND="
+	boost? ( dev-libs/boost:0= )
+	mpi? ( sys-cluster/ampi:0= )
+	sparse? ( sci-libs/colpack:0= )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MYPN}-${PV}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.5.0-no-colpack.patch
+	"${FILESDIR}"/${PN}-2.5.0-pkgconfig-no-ldflags.patch
+	"${FILESDIR}"/${PN}-2.6.2-dash.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-advanced-branching \
+		--enable-atrig-erf \
+		$(use_enable mpi ampi) \
+		$(use_enable sparse) \
+		$(use_enable static-libs static) \
+		$(use_with boost) \
+		$(use_with sparse colpack "${EPREFIX}"/usr)
+}
+
+src_test() {
+	emake test
+}
+
+src_install() {
+	default
+	use static-libs || prune_libtool_files --all
+}