sys-kernel/gentoo-kernel-bin: bump to 5.11.11 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 116 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 9fd0334335e1..2504aab89d0d 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -41,6 +41,7 @@ DIST gentoo-kernel-5.11.10-1.amd64.xpak 64501303 BLAKE2B d1bd941d62520fe0a2b7156
 DIST gentoo-kernel-5.11.10-1.arm64.xpak 59801228 BLAKE2B 1ce4d7955ad3d32abe57ac01f008d7dd8b811fad2658c09b03069bad693d9b653262e0c69abfa65ff1ee2a2117cfc92427c644de53971fa70ce4b99fd360a28e SHA512 2375505cf7ff4ddeed3f352049fd6b041b3449e9cf021fdd8bd59d7661ac17434a75e5e3aef85134185a50ec5832b11a260ad4f4e395ab3d6db4b95664b041ab
 DIST gentoo-kernel-5.11.10-1.x86.xpak 57456795 BLAKE2B 8245a1da8c783456bcaff4a5ca2ded9ffadf03d2cf858a689ee9a5003ab495461f3640bd5ac9c16bdd5f7e7dda1dacb73b512e065b2c5c7038f5422ca9df599b SHA512 af4b8126200b45faa5173bbe325469e6c0f233ff70f2da476d059ef2f92f21d2e6931313fb6d43b4cf6c47570f54b305b47595067ca3fc083b98864959f5acf1
 DIST gentoo-kernel-5.11.11-1.amd64.xpak 64531577 BLAKE2B 2c7f94f0288b77f16c1b9770e5a31fd7c50dad7c9dbfb5728b348d19c2c8834a4df9f506de04ecc5729cbc5c39468e1afe69db2c8ecfa9d926d051bb4aa6f1a5 SHA512 a35e580c8aabff1f39f177a3c01ef61a53f7d0c5541585f444ead741718a6822074c5b8b29bf73ebb4c954baa4ee225a4d547707fe4d8f04007c390c4a05838b
+DIST gentoo-kernel-5.11.11-1.arm64.xpak 59829994 BLAKE2B d12c066c27cab9480f9341b5fc1b4b58f439e0622b8b491ed78c56129becd8c858ea1278ee3a164d2de8ea7f9dfcb7265360478db92c22a8f5c28ed11f2bf3fb SHA512 ea076e166644984bb88209ff43ac566d21219e6a4f7d4cab8750ef22038822b50a3c98897f62d1761f33e4acedc0b680b31885bace70844387e68d780f94e775
 DIST gentoo-kernel-5.11.11-1.x86.xpak 57470778 BLAKE2B abf3c054de67118de4adf50121ffef53ac206e7c439d6b4f71e2044573fbc8f42ece325c18c1f706c21d2e87472c3419e9195058ba8f4eb3e44ccd7fe8a443b7 SHA512 1b01790396650f6db68621e1febf2810835a03ce2f5a872b5f8d9e5f01cb6cce0bf5490e582c4aaa5aa953b6ac3a125a450c2911ab0080d20df59493366bbacc
 DIST gentoo-kernel-5.11.5-1.amd64.xpak 64924579 BLAKE2B b4484bb69d8355f63acecadac5a604ab57f61ae87a4341cba16c6b3cdc35d19c64c6d8042fedc69aa1272c151d09ba5957b9b26f2a6ab067a46451fd0a928b9b SHA512 218d649adc456f13055e7ec7ce3de1ead2cfdcc41d6d5d023de67dcc7a21679154dfe057dcf72592ab7a7315a8cf1a4d7a96f7904c21f0f8e219f3a277dae21f
 DIST gentoo-kernel-5.11.5-1.arm64.xpak 59869818 BLAKE2B 26d4431d1e9e3dd58f1d352ab872cf2749d64ae768a114d42cf1bf3ac342c9792dfa19ccd1bf502ea26ee99a0bb00e75783b2958726d5073d8f69c3f66e29a9c SHA512 ea64669b86cb1a3c86f92016f8a9838eabf1328c9a996084c8e8226b736d526b7d246f42d24ff9d07d2d0606cc0db914251b7007caa74080a482c0bcdd4a0bc6
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.11-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.11-r1.ebuild
new file mode 100644
index 000000000000..2760e617c656
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.11-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}