sys-kernel/gentoo-kernel-bin: bump to 5.4.127 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 115 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 2ca469777cde..c5c613389f8b 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -51,6 +51,7 @@ DIST gentoo-kernel-5.4.126-1.amd64.xpak 61351554 BLAKE2B 9aadbf998b8cd535f6e8cb8
 DIST gentoo-kernel-5.4.126-1.arm64.xpak 56367523 BLAKE2B fb9ff4bb7e39bbdccc43b10fe4e94ef3c71ec97546d8b9a6cfcd71e86532700867959c298dc276d1f1da443c551c312b769a185dc9dbdd0c100cb6e509468f1f SHA512 e231972171447ba6586c51b979415f0fb5ce3bb7c002a4ce12c8d166d732d73850a82b978ea2b9a15d93ae9f4be9241106f3d50abd30aa9c05d4805526c4904e
 DIST gentoo-kernel-5.4.126-1.x86.xpak 53132617 BLAKE2B f258618c899740fe2e7d2fad65d3e589b0a48a7057a11f57ceafbf84900cf8ba1eec594d93960a0686378575238f3b2841921c3805ea82e4d8b666f36fb95981 SHA512 cd9489c2e4d2142237d4bdc7c473c6122eff0ff69a48d49f7d43082665dd62c58eb4f2f41b2de55c4a31da62c1826cc2a26b8561a062b55bf504f7eec3c68f97
 DIST gentoo-kernel-5.4.127-1.amd64.xpak 61364361 BLAKE2B 9ff813492bd7bc1f135b36bc323b8a2cf45407ecb0ab48cc9a69ad5f7677c02b678844dc33e2700bd23aeacbb468bba1b082b3a13d7c112b317f3aa6442cd406 SHA512 76abd4492ca0abf2017f14d6545aecbf49ff68addef44a0f6197cbd3ec1d5f45d53162afab355c9abc43e0b51d5069e76f1c06d71c137c2df4817011a2bc3e87
+DIST gentoo-kernel-5.4.127-1.arm64.xpak 56394161 BLAKE2B e3b9dc7334615ed225ba0cf71f18e45d7f4c0afb82f467597801094361df137feda3c26051c4bb1eef76b9bf9c77394b6029d4fe703746262f1fe3e7ce623ca9 SHA512 2f59983a0e5ca2e08c598aada66e3d5c052a0f67448bf979261d75e0e38d8f0e5e3921aa4f09564709262d86aac2361ccb367c6ba78addba6a6731eb98a10c87
 DIST gentoo-kernel-5.4.127-1.x86.xpak 53135461 BLAKE2B f363e24cdeae29dad876a1aaa8c0159d627d27d632de2d9509cc4f78cea4cc8ce963956771b542219f9a948e8b1a2d6aa5b80878a21d99cc0c1c3bbdc14f538c SHA512 9f9bb382a88c4f73b94956cb765c9ef5e380ee4e12b67ffb22cbfc8815bdcbf1a62b68ba770fe03d7ec3d753bbb8b3c11845ebcfcb2ef263cab9442c9fe0d340
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.12.tar.xz 118112412 BLAKE2B 842d921b9a73d2aaade763dbd2ec67bdfe0275baa6d628b775f5c87574ad7dc86f0419afcd48c10c1235f4bffa16084243f2cf4556e6afcd391e975fe8ba530b SHA512 be03b6fee1d1ea8087b09874d27c0a602c0b04fd90ad38b975bd2c8455a07e83c29b56814aaf1389e82305fae0e4c2d1701075a7f0a7295dd28149f967ec5b3d
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.127-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.127-r1.ebuild
new file mode 100644
index 000000000000..b63276300c50
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.127-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}