sys-kernel/gentoo-kernel-bin: bump to 5.11.17 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 116 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 29d407bc9a0a..1c0cf4c34a63 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -72,6 +72,7 @@ DIST gentoo-kernel-5.11.16-1.amd64.xpak 65844402 BLAKE2B 13a0ffb59cfb9ade1f99ce6
 DIST gentoo-kernel-5.11.16-1.x86.xpak 57639335 BLAKE2B 2bb1d74691e8808ed4274b617dcf2920f5b5d1e1997ab3e336afb2d909dd4221a8acabe58b50cb90853e556caa64a2240cf6844cfde515286e7644a1463e065f SHA512 8cb39baef55953fa39a8ff6884ba27ad7555472bdac99689de1965e247fab9cc1874584a1b023457d44a80b4c7482bb92133f016323be94fc93e23b34f116952
 DIST gentoo-kernel-5.11.16-2.arm64.xpak 59712835 BLAKE2B e87d91e937a21779bf92ffb97c6b6117db5006610923e7e037106eca0c2f5b3db199f32c0b0d5c9b26b8f7714e1712b6c6395a82f02e222626ed17820a6ec8f9 SHA512 6fc39015f785ab36f52dd667eeb0802628e900b123c4723be8707efc2eaea021fd210d56cec16f52b94789da576206c4d0830055b72a03b82c238d3ce26a31f8
 DIST gentoo-kernel-5.11.17-1.amd64.xpak 65875998 BLAKE2B 7cc50e3dda86d12594b42eff1221e437d41de7a1e7e31255741e3e43b036a6472f0d11e31de7e5a88cbb5b78dbdc172261aa7a91f6fe0299ebd91724517480e3 SHA512 0bb7d5f288defb7c5e01a7caecd1ae0fc8ac32e367d0910ef38c0f006efc841cc60dc1c83958db5e44452d68f6888b815f498eca0c4a6f2a16702581c71e536d
+DIST gentoo-kernel-5.11.17-1.arm64.xpak 59810001 BLAKE2B 4b273905836750c6f2ec2732de4606316bc5e58eb2afbba4302f4d0a743f1e5ca423b158bf980a34cfdbe53847f7fa28b5b054ef2f03fc59835ad100e9042ffc SHA512 07766090431c0f498ff90e60ab24e5b77c8ac273bcbbf62f8e64b702c7db7bfbb2f7430641c1db0a1cf71854efeb45f437bbcdbd51592a0338d7e626719c0007
 DIST gentoo-kernel-5.11.17-1.x86.xpak 57637749 BLAKE2B 9895d3b82d997f882684822cab8d726d8766992b2c5c7d4012135bf7274e51a8ae30e531d34fc2d4da679361785afe947e28cfc17154ebba965da96b9aaf472d SHA512 fc21308734dfd9968d97a6b7ab12c9673fb6b5bc8fbb679aace38ddc8258e132c62eb5258d96ba0d5b771326952ad80c7be790fc1c3a8993091f04d27c6a2d08
 DIST gentoo-kernel-5.11.18-1.amd64.xpak 65852667 BLAKE2B 29ddd550bd6cfec25809c53875bb96ac0c61418fc2707435e2e6571e581dc8df7e0986615073b3e9226eefbe6f587e454b4710a3a876550aa2f4f582001d031e SHA512 fa5af0e8a3bcfc2058b5cb5449707e1e156df6095ceb2ac7d75466fd181e0d0f15bb637671c17876817b82471853581a1feaa32102733c60193dd0d26ffee61d
 DIST gentoo-kernel-5.11.18-1.x86.xpak 57632889 BLAKE2B 449dfd81cb72441bb85baa686f3ac6c17f54febd6ad8a48b9c16ee7c3821dc2fc0a5e44480fdec74fb28cf345864a72c4493335d23ffa4735cd7735a1cc9fc93 SHA512 564e98fc485c43b65aa3a1a6e40b30d03ea8927a2588ee82d9f890704db7d51002400c59b75455366e2d86dd59ccbec74f18d1ef5e906bbd2a084f22b66f3d30
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.17-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.17-r1.ebuild
new file mode 100644
index 000000000000..2760e617c656
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.11.17-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~alicef/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}