sys-kernel/gentoo-kernel-bin: bump to 5.12.10 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 116 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 101377d9c493..20fbde675733 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -65,6 +65,7 @@ DIST gentoo-kernel-5.11.22-1.amd64.xpak 65882786 BLAKE2B aa98de82c4f47a586474f6f
 DIST gentoo-kernel-5.11.22-1.arm64.xpak 59725454 BLAKE2B bffe7733b1ab766ab7afae20c77696ab36bed989dae7fef60e6eba752da8f918240e0d28fdce01d5813775c4013df80ba495e6ed7163838bde2896ffce96fb06 SHA512 8b1e4b0f6ca7294a457574f23557df1cc99dc6be41f3a36f6a871cb8a21d52f0556279afe400301bbdf715d4e07134da845c37318a1e6df9e14e379cf4252f68
 DIST gentoo-kernel-5.11.22-1.x86.xpak 57639501 BLAKE2B 5d4cb13fcf9d60f0865d1048985a920a85cd13aac338c475a0cf3c2ebdc2414b5130b6d511456d52881ef37bf0f8623cb3b60694d990a274ae1e048788f44f02 SHA512 c116911b8941980ceb1026d603c038758dca821a390274b5165dc9e101962872b8051889e5685ea304d51996be602170c5aea5080f7e66421f707d4563974df7
 DIST gentoo-kernel-5.12.10-1.amd64.xpak 66370289 BLAKE2B 74f9046d711902b5cb650c0c1eac07f4dab42037fc93ee3f9ec70b14a708d1244ec65d54e11e1ab169384bdf2663816dba33e58d22853f30133341296ce65db8 SHA512 e42a2d5122d17a6abfe75c17585e96d0fcb87ab21dd3bfbddce6f22c7b73b66daf358b642c4b3658d2d5e43a3c586da5bd48e90e00520ec2cbd696493510f410
+DIST gentoo-kernel-5.12.10-1.arm64.xpak 62567249 BLAKE2B e20ff0b59f3f0781cbb7d1a2eb290e46cdb8fc0f4aa189bb70f7ad5d02b54a5a30bdb3d91c779bfdb04daf01efe5c85376c4a3faa52cead80743aae588993e26 SHA512 ee5daf6872844476018ddab8445e3dbd25d1585a8cd2b6195028b8f8690cb262befcfdef3e0267a422f30c4ca0036dd6c985331cbacdc0c8e79f9c7c9755f4ba
 DIST gentoo-kernel-5.12.10-1.x86.xpak 58113734 BLAKE2B 093fc8ae00efefb2eb38cd0ce145f16e046be2f5110ad18d957ae122b97a1d4a6e6d8cce4c42f53ece1dabe9ebd99640c922686a8a00f7186bdc5f8b82f44144 SHA512 5c58a7277e1c3b1017ead2584dd6c768b2b4476f0da0c3dbd28facec64c1f37a3db9119d869720f6f63e3e1c53ffb8d69efef8f5008e0a71f8f55098d2ce9d83
 DIST gentoo-kernel-5.12.6-1.amd64.xpak 66353212 BLAKE2B 978e03073a562ca7b73f2e825964e834bace17a4c8d8e7eeadcdad2acaea912ff05d5eb3281a29d42c3fa8c4dc9638528abb9bcecb65b58fffb7d9ad2f5fd245 SHA512 f7c411047069e32a6b43b9bb85ea3457e014f1fbeebd2324646b5d5987e6c3929df04273a0ce4433d2afed9818ff45243d23ebb2e9fe75b48db27a31bec770cd
 DIST gentoo-kernel-5.12.6-1.arm64.xpak 60212554 BLAKE2B 5cd63259c7797c3f65c4dca4f845cc967097c35428ce80581bdd9be6d339651ea11ef79963ae0ae3b56897f218e31493b7c28d76a11d31fae87ae7ea44042523 SHA512 d92e8fea3c8ec1a7f238c7a40f982af3ec4592d7a625185e6b44d4881224c77bf58483b21ccb0ceffb279a954f7aaf1f173ab607fe36b58f61340a2731278ebe
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.10-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.10-r1.ebuild
new file mode 100644
index 000000000000..9cc54d1c175f
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.10-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}