x11-apps/igt-gpu-tools: Version bump to 1.28

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 108 insertions, 0 deletions

diff --git a/x11-apps/igt-gpu-tools/Manifest b/x11-apps/igt-gpu-tools/Manifest
index 00aa0f839161..38ce63d1d561 100644
--- a/x11-apps/igt-gpu-tools/Manifest
+++ b/x11-apps/igt-gpu-tools/Manifest
@@ -1,2 +1,3 @@
 DIST igt-gpu-tools-1.27.1-patches.tar.xz 5608 BLAKE2B 01c3cd14a7e920930dea96de6136c3b0236204998d9ad39775f6f9d6e1eb248bfb67651cabc23d50ec88b052c4e35194da2fe0ac05fe7084b771892cd9e2f328 SHA512 ef00c789374bd3a2961d6d989f557026f68f94e929c74ffb1c078c6106c734960f40442cae5d3b7b2b5fef99f8ffdaccb2ef8bdb5d93fe430cc0038e5f32baa8
 DIST igt-gpu-tools-1.27.1.tar.xz 2321940 BLAKE2B b6c4fee31c97cd5005c1f2cd5c18c181582adfb27e92444a8e78d1c105acb78a424bd4e4af8d13333776c81531fbfd24dc4b7db0da9858f5b803f64962d6269d SHA512 20923505e9afe6e5064bf8f4056e027ff0321cd29d8982157a608369aea6fbef24c93756de96ef6296e09d539957fc6cdad4097cbab5af33f8828f762da0d8c0
+DIST igt-gpu-tools-1.28.tar.xz 2597284 BLAKE2B c15a5b0142f2bf54d0b002b5a17ca705b9cc33662b902edb18e0860c8a1d66c911a082f1c60b3b41f184bd72d7f568554a11d69f9b70978d176eef2cdd1f4e38 SHA512 b0bed7fce28a309f5e5b1f044952abf06ede806ef691b4ddbd52ee437bc9c3701822d65c761c69a8ae5b40695d121193f30aa772cdfaf9ab16c800d7fbcd0abc
diff --git a/x11-apps/igt-gpu-tools/igt-gpu-tools-1.28.ebuild b/x11-apps/igt-gpu-tools/igt-gpu-tools-1.28.ebuild
new file mode 100644
index 000000000000..1f80a8afe9ad
--- /dev/null
+++ b/x11-apps/igt-gpu-tools/igt-gpu-tools-1.28.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+EGIT_REPO_URI="https://gitlab.freedesktop.org/drm/${PN}.git"
+if [[ ${PV} = *9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit ${GIT_ECLASS} meson python-any-r1
+
+DESCRIPTION="Intel GPU userland tools"
+
+HOMEPAGE="https://gitlab.freedesktop.org/drm/igt-gpu-tools"
+if [[ ${PV} != *9999* ]]; then
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://www.x.org/releases/individual/app/${P}.tar.xz"
+fi
+LICENSE="MIT"
+SLOT="0"
+IUSE="chamelium doc man overlay runner tests unwind valgrind video_cards_amdgpu video_cards_intel video_cards_nouveau X xv"
+REQUIRED_USE="
+	|| ( video_cards_amdgpu video_cards_intel video_cards_nouveau )
+	overlay? (
+		video_cards_intel
+		|| ( X xv )
+	)
+	doc? ( tests )
+	runner? ( tests )
+"
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/elfutils
+	dev-libs/glib:2
+	sys-apps/kmod
+	sys-libs/zlib:=
+	sys-process/procps:=
+	virtual/libudev:=
+	>=x11-libs/cairo-1.12.0[X?]
+	>=x11-libs/libdrm-2.4.82[video_cards_amdgpu?,video_cards_intel?,video_cards_nouveau?]
+	>=x11-libs/libpciaccess-0.10
+	x11-libs/pixman
+	chamelium? (
+		dev-libs/xmlrpc-c:=[curl]
+		sci-libs/gsl:=
+		media-libs/alsa-lib
+	)
+	overlay? (
+		>=x11-libs/libXrandr-1.3
+		xv? (
+			x11-libs/libX11
+			x11-libs/libXext
+			x11-libs/libXv
+		)
+	)
+	runner? ( dev-libs/json-c:= )
+	unwind? ( sys-libs/libunwind:= )
+	valgrind? ( dev-debug/valgrind )
+	"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-util/gtk-doc-1.25-r1 )
+	man? ( dev-python/docutils )
+	overlay? (
+		>=dev-util/peg-0.1.18
+		x11-base/xorg-proto
+	)
+	video_cards_intel? (
+		app-alternatives/yacc
+		app-alternatives/lex
+	)
+"
+BDEPEND="${PYTHON_DEPS}"
+
+src_prepare() {
+	sed -e "s/find_program('rst2man-3'/find_program('rst2man.py', 'rst2man-3'/" -i man/meson.build
+	default_src_prepare
+}
+
+src_configure() {
+	local gpus=""
+	use video_cards_amdgpu  && gpus+="amdgpu,"
+	use video_cards_intel   && gpus+="intel,"
+	use video_cards_nouveau && gpus+="nouveau,"
+
+	local overlay_backends=""
+	use overlay && use xv && overlay_backends+="xv,"
+	use overlay && use X && overlay_backends+="x,"
+
+	local emesonargs=(
+		$(meson_feature overlay)
+		-Doverlay_backends=${overlay_backends%?}
+		$(meson_feature chamelium)
+		$(meson_feature valgrind)
+		$(meson_feature man)
+		-Dtestplan=disabled
+		-Dsphinx=disabled
+		$(meson_feature doc docs)
+		$(meson_feature tests)
+		-Dxe_driver=disabled
+		-Dlibdrm_drivers=${gpus%?}
+		$(meson_feature unwind libunwind)
+		$(meson_feature runner)
+	)
+	meson_src_configure
+}