x11-libs/libdrm: Version bump to 2.4.105

Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 73 insertions, 1 deletions

diff --git a/x11-libs/libdrm/Manifest b/x11-libs/libdrm/Manifest
index b2a8365b41dd..0fcd194739f0 100644
--- a/x11-libs/libdrm/Manifest
+++ b/x11-libs/libdrm/Manifest
@@ -1,2 +1,3 @@
 DIST libdrm-2.4.103.tar.xz 412796 BLAKE2B 64904bebb923d79b83fbe1949aa24c697cff2a258f415c4633991f938772980e985df19f44df881d10b14268ea414ff99220c8f003ad09ac1decdc6c85249240 SHA512 15b098b962008271400692b6b15ecb7e22676f8698e0220ad969735ac2315ccc737d19558afb6abda82bae15117e5f306c048184a2369f434b85ecaa670ca885
 DIST libdrm-2.4.104.tar.xz 419372 BLAKE2B 4f9c1d88e8e13e12b192b822aaddcbb01716771b85445f7468129600df3214a9dd3559539830eeec4df61f03c187fa88a6d0bb2d5278a5125d2aa11cef6805ea SHA512 0fdbef53e0e7c441c805c95ac55ca2c94f11e8fa18e36b4dc7534c22e2b5bc8eca7283fdf41785da753f98d0b589023111abdba70db7e79837729b1540253d6e
+DIST libdrm-2.4.105.tar.xz 420376 BLAKE2B 1443dd378263358e7af64ee63ac6d25d2c5efaacaf2f76be1a0021f03dd08ce4580ef8531af076504c5a29e538d5c66d1773fb0439dd8bc312f3a038535dd07d SHA512 083a04af7208e58be21b89c6ebdbe2db3ba00cd29f0d271bd38bfe97dfca741edafddaaf9b5b95c20fac2c9b700434ea5b21397de26f7073169ad6f5b090f715
diff --git a/x11-libs/libdrm/libdrm-2.4.105.ebuild b/x11-libs/libdrm/libdrm-2.4.105.ebuild
new file mode 100644
index 000000000000..370a65ea93cc
--- /dev/null
+++ b/x11-libs/libdrm/libdrm-2.4.105.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/drm.git"
+
+if [[ ${PV} = 9999* ]]; then
+	GIT_ECLASS="git-r3"
+fi
+
+inherit ${GIT_ECLASS} meson multilib-minimal
+
+DESCRIPTION="X.Org libdrm library"
+HOMEPAGE="https://dri.freedesktop.org/ https://gitlab.freedesktop.org/mesa/drm"
+if [[ ${PV} = 9999* ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://dri.freedesktop.org/libdrm/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+VIDEO_CARDS="amdgpu exynos freedreno intel nouveau omap radeon tegra vc4 vivante vmware"
+for card in ${VIDEO_CARDS}; do
+	IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+
+IUSE="${IUSE_VIDEO_CARDS} libkms valgrind"
+RESTRICT="test" # see bug #236845
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="
+	video_cards_intel? ( >=x11-libs/libpciaccess-0.13.1-r1:=[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	valgrind? ( dev-util/valgrind )"
+
+multilib_src_configure() {
+	local emesonargs=(
+		# Udev is only used by tests now.
+		-Dudev=false
+		-Dcairo-tests=false
+		-Damdgpu=$(usex video_cards_amdgpu true false)
+		-Dexynos=$(usex video_cards_exynos true false)
+		-Dfreedreno=$(usex video_cards_freedreno true false)
+		-Dintel=$(usex video_cards_intel true false)
+		-Dnouveau=$(usex video_cards_nouveau true false)
+		-Domap=$(usex video_cards_omap true false)
+		-Dradeon=$(usex video_cards_radeon true false)
+		-Dtegra=$(usex video_cards_tegra true false)
+		-Dvc4=$(usex video_cards_vc4 true false)
+		-Detnaviv=$(usex video_cards_vivante true false)
+		-Dvmwgfx=$(usex video_cards_vmware true false)
+		-Dlibkms=$(usex libkms true false)
+		# valgrind installs its .pc file to the pkgconfig for the primary arch
+		-Dvalgrind=$(usex valgrind auto false)
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_test() {
+	meson_src_test
+}
+
+multilib_src_install() {
+	meson_src_install
+}
diff --git a/x11-libs/libdrm/libdrm-9999.ebuild b/x11-libs/libdrm/libdrm-9999.ebuild
index 48e056d6a358..370a65ea93cc 100644
--- a/x11-libs/libdrm/libdrm-9999.ebuild
+++ b/x11-libs/libdrm/libdrm-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7