x11-libs/libva-intel-driver: Version bump to 2.4.0_pre1

Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Matt Turner <mattst88@gentoo.org>

1 files changed, 54 insertions, 0 deletions

diff --git a/x11-libs/libva-intel-driver/libva-intel-driver-2.4.0_pre1.ebuild b/x11-libs/libva-intel-driver/libva-intel-driver-2.4.0_pre1.ebuild
new file mode 100644
index 000000000000..4da19b9b7c0d
--- /dev/null
+++ b/x11-libs/libva-intel-driver/libva-intel-driver-2.4.0_pre1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="intel-vaapi-driver"
+if [[ ${PV} = *9999* ]] ; then # Live ebuild
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/intel/intel-vaapi-driver"
+fi
+
+inherit autotools multilib-minimal
+
+DESCRIPTION="HW video decode support for Intel integrated graphics"
+HOMEPAGE="https://github.com/intel/intel-vaapi-driver"
+if [[ ${PV} != *9999* ]] ; then
+	SRC_URI="https://github.com/intel/${MY_PN}/releases/download/${PV/_/.}/${MY_PN}-${PV/_/.}.tar.bz2"
+	S="${WORKDIR}/${MY_PN}-${PV/_/.}"
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="wayland X"
+RESTRICT="test" # No tests
+
+RDEPEND="
+	>=x11-libs/libdrm-2.4.52[video_cards_intel,${MULTILIB_USEDEP}]
+	>=x11-libs/libva-2.4.0:=[X?,wayland?,drm,${MULTILIB_USEDEP}]
+	wayland? (
+		>=dev-libs/wayland-1.11[${MULTILIB_USEDEP}]
+		>=media-libs/mesa-9.1.6[egl,${MULTILIB_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	sed -e 's/intel-gen4asm/\0diSaBlEd/g' -i configure.ac || die
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myconf=(
+		$(use_enable wayland)
+		$(use_enable X x11)
+	)
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
+}
+
+multilib_src_install_all() {
+	find "${D}" -name "*.la" -delete || die
+}