1 files changed, 54 insertions, 0 deletions
diff --git a/app-shells/mksh/mksh-57-r2.ebuild b/app-shells/mksh/mksh-57-r2.ebuild
new file mode 100644
index 000000000000..b818b1caf1a2
--- /dev/null
+++ b/app-shells/mksh/mksh-57-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+if [[ $PV = 9999 ]]; then
+	inherit cvs
+	ECVS_SERVER="anoncvs.mirbsd.org:/cvs"
+	ECVS_MODULE="mksh"
+	ECVS_USER="_anoncvs"
+	ECVS_AUTH="ext"
+	KEYWORDS=""
+else
+	SRC_URI="https://www.mirbsd.org/MirOS/dist/mir/mksh/${PN}-R${PV}.tgz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="MirBSD Korn Shell"
+# Host is TLSv1.0-only, keep to http for compatibility with modern browsers
+HOMEPAGE="http://mirbsd.de/mksh"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="static test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	test? (
+		dev-lang/perl
+		sys-apps/ed
+	)
+"
+
+S="${WORKDIR}/${PN}"
+
+src_compile() {
+	tc-export CC
+	use static && export LDSTATIC="-static"
+	export CPPFLAGS="${CPPFLAGS} -DMKSH_DEFAULT_PROFILEDIR=\\\"${EPREFIX}/etc\\\""
+	sh Build.sh -r || die
+}
+
+src_install() {
+	into /
+	dobin mksh
+	doman mksh.1
+	dodoc dot.mkshrc
+}
+
+src_test() {
+	./mksh test.sh -v || die
+}