1 files changed, 54 insertions, 0 deletions
diff --git a/dev-lua/luacov/luacov-0.16.0.ebuild b/dev-lua/luacov/luacov-0.16.0.ebuild
new file mode 100644
index 000000000000..2e2ad21f6de0
--- /dev/null
+++ b/dev-lua/luacov/luacov-0.16.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{1..4} luajit )
+
+inherit lua
+
+DESCRIPTION="A simple coverage analyzer for Lua scripts"
+HOMEPAGE="https://github.com/keplerproject/luacov"
+SRC_URI="https://github.com/keplerproject/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		dev-lua/busted[${LUA_USEDEP}]
+		dev-lua/lua_cliargs[${LUA_USEDEP}]
+		${RDEPEND}
+	)
+"
+
+HTML_DOCS=( "docs/." )
+
+lua_src_test() {
+	busted --lua=${ELUA} || die
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto "$(lua_get_lmod_dir)"
+	doins src/luacov.lua
+	doins -r src/luacov
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+
+	dobin src/bin/luacov
+
+	einstalldocs
+}