1 files changed, 34 insertions, 0 deletions
diff --git a/dev-python/jsondiff/jsondiff-1.3.1.ebuild b/dev-python/jsondiff/jsondiff-1.3.1.ebuild
new file mode 100644
index 000000000000..3780ec828dbf
--- /dev/null
+++ b/dev-python/jsondiff/jsondiff-1.3.1.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="Diff JSON and JSON-like structures in Python"
+HOMEPAGE="
+	https://github.com/xlwings/jsondiff/
+	https://pypi.org/project/jsondiff/"
+SRC_URI="
+	https://github.com/xlwings/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+BDEPEND="
+	test? (
+		dev-python/nose-random[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# Avoid file collision with jsonpatch's jsondiff cli.
+	sed -e "/'jsondiff=jsondiff.cli/ d" -i setup.py || die
+	distutils-r1_python_prepare_all
+}