1 files changed, 56 insertions, 0 deletions
diff --git a/dev-python/jupyter-client/jupyter-client-8.6.2.ebuild b/dev-python/jupyter-client/jupyter-client-8.6.2.ebuild
new file mode 100644
index 000000000000..2361f98a8227
--- /dev/null
+++ b/dev-python/jupyter-client/jupyter-client-8.6.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Jupyter protocol implementation and client libraries"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/jupyter_client/
+	https://pypi.org/project/jupyter-client/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/jupyter-core-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.2[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-23.0[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.0[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib-metadata-4.8.3[${PYTHON_USEDEP}]
+	' 3.{8,9})
+"
+BDEPEND="
+	test? (
+		>=dev-python/ipykernel-6.14[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.18[${PYTHON_USEDEP}]
+		>=dev-python/pytest-jupyter-0.4.1[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: times out
+		tests/test_client.py::TestAsyncKernelClient::test_input_request
+		# TODO
+		tests/test_multikernelmanager.py::TestKernelManager::test_tcp_cinfo
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o tmp_path_retention_policy=all \
+		-p asyncio -p rerunfailures --reruns=3 -p timeout
+}