1 files changed, 43 insertions, 0 deletions
diff --git a/dev-python/keyring/keyring-22.3.0.ebuild b/dev-python/keyring/keyring-22.3.0.ebuild
new file mode 100644
index 000000000000..d62127ef81b5
--- /dev/null
+++ b/dev-python/keyring/keyring-22.3.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( pypy3 python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Provides access to the system keyring service"
+HOMEPAGE="https://github.com/jaraco/keyring"
+SRC_URI="https://github.com/jaraco/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="PSF-2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	dev-python/secretstorage[${PYTHON_USEDEP}]
+	dev-python/entrypoints[${PYTHON_USEDEP}]
+	dev-python/jeepney[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/importlib_metadata[${PYTHON_USEDEP}]
+	' pypy3 python3_7)
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/jaraco-packaging \
+	dev-python/rst-linker
+
+python_prepare_all() {
+	rm tests/backends/test_kwallet.py || die
+
+	distutils-r1_python_prepare_all
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}