1 files changed, 54 insertions, 0 deletions
diff --git a/dev-python/pyproj/pyproj-3.5.0.ebuild b/dev-python/pyproj/pyproj-3.5.0.ebuild
new file mode 100644
index 000000000000..2b285916270b
--- /dev/null
+++ b/dev-python/pyproj/pyproj-3.5.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python interface to the PROJ library"
+HOMEPAGE="
+	https://github.com/pyproj4/pyproj/
+	https://pypi.org/project/pyproj/
+"
+SRC_URI="
+	https://github.com/pyproj4/pyproj/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux"
+
+RDEPEND="
+	>=sci-libs/proj-9.0.0:=
+	dev-python/certifi[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	# Avoid greedily trying -L/usr/lib, etc
+	# https://github.com/pyproj4/pyproj/blob/main/setup.py#L76
+	export PROJ_LIBDIR="${ESYSROOT}/usr/$(get_libdir)"
+	export PROJ_INCDIR="${ESYSROOT}/usr/include"
+}
+
+python_test() {
+	rm -rf pyproj || die
+	epytest -m "not network" test
+}