1 files changed, 45 insertions, 0 deletions
diff --git a/dev-ruby/pdf-reader/pdf-reader-2.14.1.ebuild b/dev-ruby/pdf-reader/pdf-reader-2.14.1.ebuild
new file mode 100644
index 000000000000..6bed900e3d0c
--- /dev/null
+++ b/dev-ruby/pdf-reader/pdf-reader-2.14.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GITHUB_USER=yob
+
+USE_RUBY="ruby31 ruby32 ruby33"
+
+RUBY_FAKEGEM_RECIPE_TEST="rspec3"
+
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG README.md TODO"
+
+RUBY_FAKEGEM_GEMSPEC="pdf-reader.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="PDF parser conforming as much as possible to the PDF specification from Adobe"
+HOMEPAGE="https://github.com/yob/pdf-reader/"
+
+# We cannot use the gem distributions because they don't contain the
+# tests' data, we have to rely on the git tags.
+SRC_URI="https://github.com/${GITHUB_USER}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+
+ruby_add_rdepend ">=dev-ruby/afm-0.2.1 =dev-ruby/afm-0.2*
+	|| ( >=dev-ruby/ascii85-2.0.1:2 dev-ruby/ascii85:0 )
+	=dev-ruby/hashery-2*
+	dev-ruby/ttfunk:*
+	dev-ruby/ruby-rc4"
+
+all_ruby_prepare() {
+	# Remove bundler support
+	sed -i -e '/[Bb]undler/d' spec/spec_helper.rb || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc examples/*
+}