1 files changed, 54 insertions, 0 deletions
diff --git a/dev-util/hipcc/hipcc-6.0.0-r1.ebuild b/dev-util/hipcc/hipcc-6.0.0-r1.ebuild
new file mode 100644
index 000000000000..c68b54e2dd9d
--- /dev/null
+++ b/dev-util/hipcc/hipcc-6.0.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake perl-functions llvm
+
+LLVM_MAX_SLOT=17
+
+DESCRIPTION="Radeon Open Compute hipcc"
+HOMEPAGE="https://github.com/ROCm-Developer-Tools/hipcc"
+
+KEYWORDS="~amd64"
+SRC_URI="https://github.com/ROCm-Developer-Tools/hipcc/archive/refs/tags/rocm-${PV}.tar.gz -> hipcc-${PV}.tar.gz"
+
+LICENSE="Apache-2.0 MIT"
+SLOT="0/$(ver_cut 1-2)"
+IUSE="debug test"
+RESTRICT="!test? ( test )"
+
+S=${WORKDIR}/HIPCC-rocm-${PV}
+
+DEPEND="<sys-devel/llvm-18:=
+	<sys-devel/clang-18:=
+	"
+RDEPEND="${DEPEND}
+	!<dev-util/hip-5.7"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.7.1-fno-stack-protector.patch"
+	"${FILESDIR}/${PN}-5.7.1-hipcc-hip-version.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+
+	sed -e "s:\$ROCM_PATH/llvm/bin:$(get_llvm_prefix ${LLVM_MAX_SLOT})/bin:" \
+		-i bin/hipvars.pm || die
+
+	sed -e "s:\$ENV{'DEVICE_LIB_PATH'}:'${EPREFIX}/usr/lib/amdgcn/bitcode':" \
+		-e "s:\$ENV{'HIP_LIB_PATH'}:'${EPREFIX}/usr/$(get_libdir)':" \
+		-e "/HIP.*FLAGS.*isystem.*HIP_INCLUDE_PATH/d" \
+		-e 's:${ROCM_PATH}/usr/bin/rocm_agent_enumerator:/usr/bin/rocm_agent_enumerator:' \
+		-i bin/hipcc.pl || die
+}
+
+src_install() {
+	cmake_src_install
+	# rm unwanted copy
+	rm -rf "${ED}/usr/hip" || die
+	# Handle hipvars.pm
+	rm "${ED}/usr/bin/hipvars.pm" || die
+	perl_domodule "${S}"/bin/hipvars.pm
+}