2 files changed, 64 insertions, 0 deletions
diff --git a/sys-apps/tuned/Manifest b/sys-apps/tuned/Manifest
index 28fa06f019e9..086fe3abac9f 100644
--- a/sys-apps/tuned/Manifest
+++ b/sys-apps/tuned/Manifest
@@ -1 +1,2 @@
 DIST tuned-2.15.0.tar.gz 207775 BLAKE2B 307b0598d9e99831526f2b26d5544df3832db7e17f28935c6f8d9293ec0d03729fb66906dca4739d48690e488f05383d448e7e714f6ae4824489564c295784c9 SHA512 67acdf10ecccd7910c4dcfd737610b4cb7651c7bf937bc0ed9c51869262d9f3a46f262d0b7636bc7a86a8abf579542a46f551e4f6c7561a061d8d58459be4589
+DIST tuned-2.16.0.tar.gz 213111 BLAKE2B 865cfffc89459396aa50c7908c88de405dea365084cf1592134391da961e88cc5610b663d93d531febdf881182624a13771493c61915003c59ad24bc64dd8a5c SHA512 35f04e1ee1ab3d8be711f0787db92c089cc210c75a3be0bc60389effaed8dc3fb502eff54ea0336154563f7b194f8ff286a2e408ab439a472b6d4922c64d5b03
diff --git a/sys-apps/tuned/tuned-2.16.0.ebuild b/sys-apps/tuned/tuned-2.16.0.ebuild
new file mode 100644
index 000000000000..bb7ae49d1f98
--- /dev/null
+++ b/sys-apps/tuned/tuned-2.16.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9} )
+
+inherit python-single-r1 xdg-utils tmpfiles
+
+DESCRIPTION="Daemon for monitoring and adaptive tuning of system devices"
+HOMEPAGE="https://github.com/redhat-performance/tuned"
+SRC_URI="https://github.com/redhat-performance/tuned/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/configobj[${PYTHON_USEDEP}]
+		dev-python/decorator[${PYTHON_USEDEP}]
+		dev-python/pyudev[${PYTHON_USEDEP}]
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/python-linux-procfs[${PYTHON_USEDEP}]
+	')"
+
+RDEPEND="
+	${DEPEND}
+	sys-apps/dbus
+	sys-apps/ethtool
+	sys-power/powertop
+	dev-util/systemtap"
+
+RESTRICT="test"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^PYTHON/s:/usr/bin/python3:${EPREFIX}/usr/bin/${EPYTHON}:" \
+		-e "/^export DOCDIR/s/$/&\-\$(VERSION)/g" \
+		-e "/\$(DESTDIR)\/run\/tuned/d" \
+		-e "/\$(DESTDIR)\/var\/lib\/tuned/d" \
+		-e "/\$(DESTDIR)\/var\/log\/tuned/d" \
+		Makefile || die
+}
+
+src_install() {
+	default
+
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	python_fix_shebang "${D}"
+	python_optimize
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	tmpfiles_process ${PN}.conf
+}