blob: b4f0dfcd119d84a588ef46d9ed113e3791ea1d35 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
NEED_EMACS=24.5
inherit elisp
DESCRIPTION="Yet Another Message Interface on Emacsen"
HOMEPAGE="https://github.com/wanderlust/wanderlust"
GITHUB_SHA1="769699d60aa033049804083b459ee562b82db77e"
SRC_URI="https://github.com/wanderlust/${PN}/archive/${GITHUB_SHA1}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-${GITHUB_SHA1}"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~alpha amd64 ~ia64 ppc ~ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="bbdb ssl l10n_ja"
RDEPEND=">=app-emacs/apel-10.8
>=app-emacs/flim-1.14.9
>=app-emacs/semi-1.14.7
bbdb? ( app-emacs/bbdb )"
DEPEND="${RDEPEND}"
SITEFILE="50${PN}-gentoo.el"
src_configure() {
local lang="\"en\""
use l10n_ja && lang="${lang} \"ja\""
echo "(setq wl-info-lang '(${lang}) wl-news-lang '(${lang}))" >>WL-CFG
use ssl && echo "(setq wl-install-utils t)" >>WL-CFG
}
src_compile() {
emake
emake info
}
src_install() {
emake \
LISPDIR="${ED}${SITELISP}" \
PIXMAPDIR="${ED}${SITEETC}/wl/icons" \
install
elisp-site-file-install "${FILESDIR}/${SITEFILE}" wl
insinto "${SITEETC}/wl/samples/en"
doins samples/en/*
doinfo doc/wl*.info
dodoc BUGS ChangeLog* INSTALL NEWS README.md
if use l10n_ja; then
insinto "${SITEETC}/wl/samples/ja"
doins samples/ja/*
dodoc BUGS.ja INSTALL.ja NEWS.ja README.ja.md
fi
}
|
GitWeb
