blob: 1116f0710464bf20736c5882c8a153c62d483f1c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit bash-completion-r1 cmake
DESCRIPTION="Taskwarrior is a command-line todo list manager"
HOMEPAGE="https://taskwarrior.org/"
SRC_URI="https://github.com/GothenburgBitFactory/taskwarrior/releases/download/v${PV}/${P}.tar.gz
https://github.com/GothenburgBitFactory/taskwarrior/releases/download/v${PV}/tests-${PV}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86 ~x64-macos"
IUSE="+sync"
DEPEND="
sync? ( net-libs/gnutls )
"
RDEPEND="${DEPEND}"
src_prepare() {
# move test directory into source directory
mv "${WORKDIR}"/test "${WORKDIR}"/${P} || die
cmake_src_prepare
# don't automatically install scripts
sed -i '/scripts/d' CMakeLists.txt || die
}
src_configure() {
mycmakeargs=(
-DENABLE_SYNC=$(usex sync)
-DTASK_DOCDIR=share/doc/${PF}
-DTASK_RCDIR=share/${PN}/rc
-DBUILD_SHARED_LIBS=off # bug 764224
)
cmake_src_configure
}
src_test() {
cd "${WORKDIR}"/"${P}"_build || die
eninja test
}
src_install() {
cmake_src_install
newbashcomp scripts/bash/task.sh task
# vim syntax
rm scripts/vim/README || die
insinto /usr/share/vim/vimfiles
doins -r scripts/vim/*
# zsh-completions
insinto /usr/share/zsh/site-functions
doins scripts/zsh/*
exeinto "/usr/share/${PN}/scripts"
doexe scripts/add-ons/*
}
|
GitWeb
