blob: 82d648ca221a94d51fdb732cad19a3cf04b5b06c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DESCRIPTION="Asynchronous Network Library"
HOMEPAGE="https://think-async.com https://github.com/chriskohlhoff/asio"
SRC_URI="mirror://sourceforge/${PN}/${PN}/${P}.tar.bz2"
LICENSE="Boost-1.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="doc examples ssl test"
RESTRICT="!test? ( test )"
# test searches for libssl during ./configure, and REQUIRED_USE is easier than
# patching configure to not search for it with USE=-ssl
REQUIRED_USE="test? ( ssl )"
RDEPEND="dev-libs/boost:=
ssl? (
dev-libs/openssl:0=
)"
DEPEND="${RDEPEND}"
src_prepare() {
default
if ! use test; then
# Don't build nor install any examples or unittests
# since we don't have a script to run them
cat > src/Makefile.in <<-EOF || die
all:
install:
clean:
EOF
fi
}
src_install() {
use doc && local HTML_DOCS=( doc/. )
default
if use examples; then
# Get rid of the object files
emake clean
dodoc -r src/examples
docompress -x /usr/share/doc/${PF}/examples
fi
}
|
GitWeb
