blob: 7d1bae346c2e06d04860ba675c9e2147bd77dceb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
inherit distutils-r1 eutils
DESCRIPTION="Python interface to xattr"
HOMEPAGE="http://pyxattr.k1024.org/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
http://pyxattr.k1024.org/downloads/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc64 ~s390 ~sh ~x86 ~amd64-linux ~arm-linux ~x86-linux"
IUSE="doc test"
RDEPEND="sys-apps/attr"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]
doc? ( >=dev-python/sphinx-1.3.1[${PYTHON_USEDEP}] )
test? ( dev-python/nose[${PYTHON_USEDEP}] )"
python_prepare_all() {
sed -i -e 's:, "-Werror"::' setup.py || die
# Bug 548486
sed -e "s:html_theme = 'default':html_theme = 'classic':" \
-i doc/conf.py || die
distutils-r1_python_prepare_all
}
python_compile_all() {
use doc && emake doc
}
src_test() {
# Perform the tests in /var/tmp; that location is more likely
# to have xattr support than /tmp which is often tmpfs.
export TESTDIR=/var/tmp
einfo 'Please note that the tests fail if xattrs are not supported'
einfo 'by the filesystem used for /var/tmp.'
distutils-r1_src_test
}
python_test() {
nosetests || die "Tests fail with ${EPYTHON}"
}
python_install_all() {
use doc && local HTML_DOCS=( doc/html/. )
distutils-r1_python_install_all
}
|
GitWeb
