blob: 1c6df5309aaf21075a00115b33f1c51a7a9a09ee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
KDE_HANDBOOK="forceoptional"
KDE_TEST="optional"
VIRTUALX_REQUIRED="test"
inherit kde5
DESCRIPTION="KDE Archiving tool"
HOMEPAGE="https://www.kde.org/applications/utilities/ark
https://utils.kde.org/projects/ark"
KEYWORDS="amd64 x86"
IUSE="bzip2 lzma zlib"
RDEPEND="
$(add_frameworks_dep karchive)
$(add_frameworks_dep kcompletion)
$(add_frameworks_dep kconfig)
$(add_frameworks_dep kconfigwidgets)
$(add_frameworks_dep kcoreaddons)
$(add_frameworks_dep kcrash)
$(add_frameworks_dep kdbusaddons)
$(add_frameworks_dep ki18n)
$(add_frameworks_dep kiconthemes)
$(add_frameworks_dep kio)
$(add_frameworks_dep kjobwidgets)
$(add_frameworks_dep kparts)
$(add_frameworks_dep kpty)
$(add_frameworks_dep kservice)
$(add_frameworks_dep kwidgetsaddons)
$(add_frameworks_dep kxmlgui)
$(add_qt_dep qtdbus)
$(add_qt_dep qtgui)
$(add_qt_dep qtwidgets)
>=app-arch/libarchive-3.1.0[bzip2?,lzma?,zlib?]
"
DEPEND="${RDEPEND}
$(add_qt_dep qtconcurrent)
sys-devel/gettext
"
# bug #560548, last checked with 16.04.1
RESTRICT="test"
PATCHES=( "${FILESDIR}/${PN}-16.12.0-disable-executables.patch" )
src_configure() {
local mycmakeargs=(
$(cmake-utils_use_find_package bzip2 BZip2)
$(cmake-utils_use_find_package lzma LibLZMA)
$(cmake-utils_use_find_package zlib ZLIB)
)
kde5_src_configure
}
pkg_postinst() {
kde5_pkg_postinst
if ! has_version app-arch/unar ; then
elog "For handling rar archives, install app-arch/unar"
fi
if ! has_version app-arch/p7zip ; then
elog "For handling 7-Zip archives, install app-arch/p7zip"
fi
}
|
GitWeb
