blob: 729b95594e1f26af3c51693c9e4222f9b623e75c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit autotools linux-info multilib user
DESCRIPTION="A client implementation of Secure Socket Tunneling Protocol (SSTP)"
HOMEPAGE="http://sstp-client.sourceforge.net/"
SRC_URI="mirror://sourceforge/sstp-client/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="static"
RDEPEND=">=dev-libs/libevent-2.0.10
dev-libs/openssl:0
net-dialup/ppp:="
DEPEND="${RDEPEND}
virtual/pkgconfig"
CONFIG_CHECK="~NETFILTER_NETLINK"
DOCS=( AUTHORS ChangeLog DEVELOPERS INSTALL NEWS README TODO USING )
pkg_setup() {
enewgroup sstpc
enewuser sstpc -1 -1 -1 sstpc
}
src_prepare() {
# set proper examples dir, --docdir overriding is src_configure does not work
sed -i -e "/^docdir/s:@PACKAGE@:${PF}/examples:" Makefile.am || die 'sed on Makefile.am failed'
default
eautoreconf
}
src_configure() {
local PPPD_VER="$(best_version net-dialup/ppp)"
PPPD_VER=${PPPD_VER#*/*-} #reduce it to ${PV}-${PR}
PPPD_VER=${PPPD_VER%%[_-]*} # main version without beta/pre/patch/revision
econf \
--enable-ppp-plugin \
--enable-group=sstpc \
--enable-user=sstpc \
--with-pppd-plugin-dir="/usr/$(get_libdir)/pppd/${PPPD_VER}" \
--with-runtime-dir="/run/sstpc" \
$(use_enable static)
}
src_install() {
default
prune_libtool_files --modules
}
|
GitWeb
