blob: 4c28e0f6687948f1dd087bb328e55e6e85a93d45 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit go-module shell-completion systemd
DESCRIPTION="Main implementation of IPFS"
HOMEPAGE="https://ipfs.io/ https://github.com/ipfs/kubo/"
SRC_URI="https://github.com/ipfs/${PN}/releases/download/v${PV}/kubo-source.tar.gz -> ${P}.tar.gz"
LICENSE="Apache-2.0 BSD BSD-2 CC0-1.0 ISC MIT MPL-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
DEPEND="
acct-group/ipfs
acct-user/ipfs
sys-fs/fuse:0
"
RDEPEND="${DEPEND}"
BDEPEND="dev-lang/go"
DOCS=( CHANGELOG.md CONTRIBUTING.md README.md docs/ )
S="${WORKDIR}"
src_compile() {
local mygoargs
mygoargs=(
-tags release
)
ego build "${mygoargs[@]}" -o ipfs ./cmd/ipfs
ego build "${mygoargs[@]}" -o ipfswatch ./cmd/ipfswatch
IPFS_PATH="" ./ipfs commands completion bash > ipfs-completion.bash || die
IPFS_PATH="" ./ipfs commands completion fish > ipfs-completion.fish || die
}
src_test() {
ego test ./cmd/ipfs/... ./cmd/ipfswatch/...
}
src_install() {
dobin ipfs
dobin ipfswatch
newbashcomp ipfs-completion.bash ipfs
newfishcomp ipfs-completion.fish ipfs
einstalldocs
systemd_dounit "${FILESDIR}/ipfs.service"
systemd_newunit "${FILESDIR}/ipfs-at.service" "ipfs@.service"
newinitd "${FILESDIR}/ipfs.init" ipfs
newconfd "${FILESDIR}/ipfs.confd" ipfs
keepdir /var/log/ipfs
fowners -R ipfs:ipfs /var/log/ipfs
}
pkg_postinst() {
elog 'To be able to use the ipfs service you will need to create the ipfs repository'
elog '(eg: su -s /bin/sh -c "ipfs init -e" ipfs)'
elog 'or change IPFS_PATH of /etc/conf.d/ipfs with another with proper permissions.'
# See https://bugs.gentoo.org/838238
ewarn 'In case kubo CPU usage is too high run the next workaround'
ewarn 'su -s /bin/sh -c "ipfs config profile apply lowpower" ipfs'
ewarn 'Be aware that this will make your node less visible to other peers'
}
|
GitWeb
