blob: 9a1017c7c4bec9ba7f399236a1a324ce2b12a5d5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit eutils fortran-2 cmake-utils multilib flag-o-matic toolchain-funcs
LPN=lapack
LPV=3.6.0
DESCRIPTION="C wrapper interface to the F77 reference BLAS implementation"
HOMEPAGE="http://www.netlib.org/cblas/"
SRC_URI="http://www.netlib.org/${LPN}/${LPN}-${LPV}.tgz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos"
IUSE=""
DEPEND="app-eselect/eselect-cblas
>=virtual/blas-3.6
virtual/pkgconfig"
RDEPEND="${DEPEND}"
S="${WORKDIR}/${LPN}-${LPV}"
PATCHES=( "${FILESDIR}/lapack-fix-build-system.patch" )
src_prepare() {
epatch "${PATCHES[@]}"
eapply_user
ESELECT_PROF=reference
cp "${FILESDIR}"/eselect.cblas.reference-r2 "${T}"/eselect.cblas.reference || die
sed -i -e "s:/usr:${EPREFIX}/usr:" "${T}"/eselect.cblas.reference || die
if [[ ${CHOST} == *-darwin* ]] ; then
sed -i -e 's/\.so\([\.0-9]\+\)\?/\1.dylib/g' \
"${T}"/eselect.cblas.reference || die
fi
sed -i \
-e 's:/CMAKE/:/cmake/:g' \
CBLAS/CMakeLists.txt || die
}
src_configure() {
local mycmakeargs=(
-Wno-dev
-DCBLAS=ON
-DUSE_OPTIMIZED_BLAS=ON
-DBLAS_LIBRARIES="$($(tc-getPKG_CONFIG) --libs blas)"
-DCMAKE_C_FLAGS="$($(tc-getPKG_CONFIG) --cflags blas) ${CFLAGS}"
-DCMAKE_Fortran_FLAGS="$($(tc-getPKG_CONFIG) --cflags blas) $(get_abi_CFLAGS) ${FCFLAGS}"
-DBUILD_SHARED_LIBS=ON
-DBUILD_STATIC_LIBS=ON
)
cmake-utils_src_configure
}
src_compile() {
cmake-utils_src_compile -C CBLAS
}
src_install() {
cmake-utils_src_install -C CBLAS
mkdir -p "${ED}/usr/$(get_libdir)/blas/reference" || die
mv "${ED}/usr/$(get_libdir)"/lib* "${ED}/usr/include"/cblas* \
"${ED}/usr/$(get_libdir)/pkgconfig"/* \
"${ED}/usr/$(get_libdir)/blas/reference" || die
rmdir "${ED}/usr/$(get_libdir)/pkgconfig" || die
rmdir "${ED}/usr/include" || die
rm -rf "${ED}"/usr/lib/ || die
eselect cblas add $(get_libdir) "${T}"/eselect.cblas.reference ${ESELECT_PROF}
}
pkg_postinst() {
local p=cblas
local current_lib=$(eselect ${p} show | cut -d' ' -f2)
if [[ ${current_lib} == ${ESELECT_PROF} || -z ${current_lib} ]]; then
# work around eselect bug #189942
local configfile="${EROOT}"/etc/env.d/${p}/$(get_libdir)/config
[[ -e ${configfile} ]] && rm -f ${configfile}
eselect ${p} set ${ESELECT_PROF}
elog "${p} has been eselected to ${ESELECT_PROF}"
else
elog "Current eselected ${p} is ${current_lib}"
elog "To use ${p} ${ESELECT_PROF} implementation, you have to issue (as root):"
elog "\t eselect ${p} set ${ESELECT_PROF}"
fi
}
|
GitWeb