blob: f634026e1cda651fc5bce00901c0c600eea2df0c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_PV=${PV/_p/pl}
MY_P=${PN}-${MY_PV}
inherit desktop dune edo
DESCRIPTION="Proof assistant written in O'Caml"
HOMEPAGE="http://coq.inria.fr/
https://github.com/coq/coq/"
SRC_URI="https://github.com/coq/coq/archive/V${MY_PV}.tar.gz
-> ${P}.tar.gz"
S="${WORKDIR}"/${MY_P}
LICENSE="LGPL-2.1"
SLOT="0/${PV}"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc gui +ocamlopt test"
RESTRICT="!test? ( test )"
RDEPEND="
dev-ml/zarith:=
|| (
dev-ml/num
<dev-lang/ocaml-4.09.0[ocamlopt?]
)
gui? (
>=dev-ml/lablgtk-3.1.2:3=[sourceview,ocamlopt?]
>=dev-ml/lablgtk-sourceview-3.1.2:3=[ocamlopt?]
)
"
DEPEND="${RDEPEND}"
BDEPEND="
dev-ml/findlib
doc? (
>=dev-java/antlr-4.7:4
dev-python/antlr4-python3-runtime
dev-python/beautifulsoup4
dev-python/pexpect
dev-python/sphinx-rtd-theme
dev-python/sphinxcontrib-bibtex
dev-tex/latexmk
dev-texlive/texlive-fontsextra
dev-texlive/texlive-latexextra
dev-texlive/texlive-xetex
media-fonts/freefont
)
test? ( dev-ml/ounit2 )
"
DOCS=( CODE_OF_CONDUCT.md CONTRIBUTING.md CREDITS INSTALL.md README.md )
src_prepare() {
# Remove failing tests. bug #904186
rm -r test-suite/coq-makefile/timing || die
default
}
src_configure() {
export CAML_LD_LIBRARY_PATH="${S}/kernel/byterun/"
dune_packages=(
coq-core
coq-stdlib
coqide-server
coq
)
use gui && dune_packages+=( coqide )
emake clean
local -a myconf=(
-prefix /usr
-libdir /usr/$(get_libdir)/coq
-mandir /usr/share/man
-docdir /usr/share/doc/${PF}
-datadir /usr/share/coq
-configdir /etc/xdg/${PN}
-native-compiler $(usex ocamlopt yes no)
)
use debug && myconf+=( -debug )
edob sh ./configure "${myconf[@]}"
}
src_compile() {
emake DUNEOPT="--display=short --profile release" VERBOSE=1 dunestrap
dune-compile ${dune_packages[@]}
use doc && emake refman-html
}
src_install() {
dune-install ${dune_packages[@]}
if use gui ; then
make_desktop_entry coqide "Coq IDE" "${EPREFIX}/usr/share/coq/coq.png"
fi
# Dune installs into /usr/<libdir>/ocaml/<coq> but
# Coq wants /usr/<libdir>/<coq> ; symlink those directories
local sym
for sym in ${dune_packages[@]} ; do
dosym $(ocamlc -where)/${sym} /usr/$(get_libdir)/${sym}
done
einstalldocs
}
|
GitWeb