blob: 61ce7f8b09e7de42efa5088cfe4fa4d7d90c36e7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
SRC_URI="
https://dev.gentoo.org/~aidecoe/distfiles/${CATEGORY}/${PN}/gentoo-logo.png"
AUTOTOOLS_AUTORECONF="1"
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="git://anongit.freedesktop.org/plymouth"
inherit git-r3
else
SRC_URI="${SRC_URI} https://www.freedesktop.org/software/plymouth/releases/${P}.tar.bz2"
fi
inherit autotools-utils readme.gentoo systemd toolchain-funcs
DESCRIPTION="Graphical boot animation (splash) and logger"
HOMEPAGE="https://cgit.freedesktop.org/plymouth/"
LICENSE="GPL-2"
SLOT="0"
[[ ${PV} == 9999 ]] || \
KEYWORDS="alpha amd64 ~arm ~ia64 ppc ppc64 sparc x86"
IUSE="debug gdm +gtk +libkms +pango static-libs"
CDEPEND="
>=media-libs/libpng-1.2.16:=
gtk? (
dev-libs/glib:2
>=x11-libs/gtk+-3.14:3
x11-libs/cairo )
libkms? ( x11-libs/libdrm[libkms] )
pango? ( >=x11-libs/pango-1.21 )
"
DEPEND="${CDEPEND}
virtual/pkgconfig
"
# Block due bug #383067
RDEPEND="${CDEPEND}
virtual/udev
!<sys-kernel/dracut-0.37-r3
"
DOC_CONTENTS="
Follow the following instructions to set up Plymouth:\n
https://dev.gentoo.org/~aidecoe/doc/en/plymouth.xml
"
PATCHES=(
"${FILESDIR}/0.9.2-systemdsystemunitdir.patch"
)
src_prepare() {
autotools-utils_src_prepare
}
src_configure() {
local myeconfargs=(
--with-system-root-install=no
--localstatedir=/var
--without-rhgb-compat-link
--enable-systemd-integration
"$(systemd_with_unitdir)"
$(use_enable debug tracing)
$(use_enable gtk gtk)
$(use_enable libkms drm)
$(use_enable pango)
$(use_enable gdm gdm-transition)
)
autotools-utils_src_configure
}
src_install() {
autotools-utils_src_install
insinto /usr/share/plymouth
newins "${DISTDIR}"/gentoo-logo.png bizcom.png
# Install compatibility symlinks as some rdeps hardcode the paths
dosym /usr/bin/plymouth /bin/plymouth
dosym /usr/sbin/plymouth-set-default-theme /sbin/plymouth-set-default-theme
dosym /usr/sbin/plymouthd /sbin/plymouthd
readme.gentoo_create_doc
# looks like make install create /var/run/plymouth
# this is not needed for systemd, same should hold for openrc
# so remove
rm -rf "${D}"/var/run
}
pkg_postinst() {
readme.gentoo_print_elog
if ! has_version "sys-kernel/dracut" && ! has_version "sys-kernel/genkernel-next[plymouth]"; then
ewarn "If you want initramfs builder with plymouth support, please emerge"
ewarn "sys-kernel/dracut or sys-kernel/genkernel-next[plymouth]."
fi
}
|
GitWeb