add mplayer2 as mplayer

Signed-off-by: Marc-Antoine Perennou <Marc-Antoine@Perennou.com>

2 files changed, 604 insertions, 0 deletions

diff --git a/media-video/mplayer2/Manifest b/media-video/mplayer2/Manifest
new file mode 100644
index 00000000..0c88cd6e
--- /dev/null
+++ b/media-video/mplayer2/Manifest
@@ -0,0 +1,4 @@
+EBUILD mplayer2-9999-r1.ebuild 15950 RMD160 51e93380361bcc12f905826b67cc43b01a01819c SHA1 fe7b9c6ad744a4e0596d3eebdfb220c909542d33 SHA256 791b4d4c1b4799802a05916d86324849a06925acc96d0ade145ba4f3c92b1cab
+DIST font-arial-iso-8859-1.tar.bz2 234242 RMD160 666697cd5efd9387057a898c714175e7c2aacbcd SHA1 152c40bf20de34aa8802d7f80d34d673b0b67212 SHA256 9730f481764f367c9089d0166fb6ccf9148808ffbbfeca635cf0e6db75765d29
+DIST font-arial-iso-8859-2.tar.bz2 222208 RMD160 562d4d92c4f5f3d537340fde3ad8d1495ac41acb SHA1 7b99bbe0e9ba89a57eccbea8f93c453c4f268181 SHA256 71debfc960007c2f6242dfc91e8b1c005b30a99e129aeb00ab8c03f4371b41c1
+DIST font-arial-cp1250.tar.bz2 249705 RMD160 a2fc7ae07b0d80936ea58e168e1047efccb9eb91 SHA1 ccf11dce5d0fb72fd3af97f788b7471cd0cd0b68 SHA256 423a07e780bb130cd8e4730715545c5d919c248dda595aab7a0a01de3c83fd12
diff --git a/media-video/mplayer2/mplayer2-9999-r1.ebuild b/media-video/mplayer2/mplayer2-9999-r1.ebuild
new file mode 100644
index 00000000..b2a2f0fa
--- /dev/null
+++ b/media-video/mplayer2/mplayer2-9999-r1.ebuild
@@ -0,0 +1,600 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+EGIT_REPO_URI="git://git.mplayer2.org/mplayer2.git"
+inherit toolchain-funcs eutils flag-o-matic multilib base git
+
+DESCRIPTION="Media Player for Linux"
+HOMEPAGE="http://www.mplayer2.org/"
+SRC_URI="
+	!truetype? (
+		mirror://mplayer/releases/fonts/font-arial-iso-8859-1.tar.bz2
+		mirror://mplayer/releases/fonts/font-arial-iso-8859-2.tar.bz2
+		mirror://mplayer/releases/fonts/font-arial-cp1250.tar.bz2
+	)
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="3dnow 3dnowext +a52 aalib +alsa altivec aqua +ass bidi bindist bl bluray
+bs2b cddb +cdio cdparanoia cpudetection custom-cpuopts custom-cflags debug dga
+directfb doc +dts +dv dvb +dvd +dvdnav dxr3 +enca esd +faad fbcon
+ftp gif ggi +iconv ipv6 jack joystick jpeg kernel_linux ladspa
+libcaca lirc +live mad md5sum +mmx mmxext mng +mp3 nas
++network nut +opengl +osdmenu oss png pnm pulseaudio pvr +quicktime
+radio +rar +real +rtc samba +shm sdl +speex sse sse2 ssse3
+tga +theora +truetype +unicode v4l v4l2 vdpau
++vorbis win32codecs +X xanim xinerama +xscreensaver +xv xvid xvmc"
+
+VIDEO_CARDS="s3virge mga tdfx vesa"
+for x in ${VIDEO_CARDS}; do
+	IUSE+=" video_cards_${x}"
+done
+
+# bindist does not cope with win32codecs, which are nonfree
+REQUIRED_USE="bindist? ( !win32codecs )"
+
+FONT_RDEPS="
+	virtual/ttf-fonts
+	media-libs/fontconfig
+	>=media-libs/freetype-2.2.1:2
+"
+# Rar: althrought -gpl version is nice, it cant do most functions normal rars can
+#	nemesi? ( net-libs/libnemesi )
+RDEPEND+="
+	virtual/ffmpeg
+	sys-libs/ncurses
+	sys-libs/zlib
+	!bindist? (
+		x86? (
+			win32codecs? ( media-libs/win32codecs )
+		)
+	)
+	X? (
+		x11-libs/libXext
+		x11-libs/libXxf86vm
+		dga? ( x11-libs/libXxf86dga )
+		ggi? (
+			media-libs/libggi
+			media-libs/libggiwmh
+		)
+		opengl? ( virtual/opengl )
+		vdpau? ( x11-libs/libvdpau )
+		xinerama? ( x11-libs/libXinerama )
+		xscreensaver? ( x11-libs/libXScrnSaver )
+		xv? (
+			x11-libs/libXv
+			xvmc? ( x11-libs/libXvMC )
+		)
+	)
+	a52? ( media-libs/a52dec )
+	aalib? ( media-libs/aalib )
+	alsa? ( media-libs/alsa-lib )
+	ass? ( ${FONT_RDEPS} >=media-libs/libass-0.9.10[enca?,fontconfig] )
+	bidi? ( dev-libs/fribidi )
+	bluray? ( media-libs/libbluray )
+	bs2b? ( media-libs/libbs2b )
+	cdio? ( dev-libs/libcdio )
+	cdparanoia? ( !cdio? ( media-sound/cdparanoia ) )
+	directfb? ( dev-libs/DirectFB )
+	dts? ( media-libs/libdca )
+	dv? ( media-libs/libdv )
+	dvb? ( media-tv/linuxtv-dvb-headers )
+	dvd? (
+		>=media-libs/libdvdread-4.1.3
+		dvdnav? ( >=media-libs/libdvdnav-4.1.3 )
+	)
+	esd? ( media-sound/esound )
+	enca? ( app-i18n/enca )
+	faad? ( media-libs/faad2 )
+	gif? ( media-libs/giflib )
+	iconv? ( virtual/libiconv )
+	jack? ( media-sound/jack-audio-connection-kit )
+	jpeg? ( virtual/jpeg )
+	ladspa? ( media-libs/ladspa-sdk )
+	libcaca? ( media-libs/libcaca )
+	lirc? ( app-misc/lirc )
+	live? ( media-plugins/live )
+	mad? ( media-libs/libmad )
+	mng? ( media-libs/libmng )
+	mp3? ( media-sound/mpg123 )
+	nas? ( media-libs/nas )
+	nut? ( >=media-libs/libnut-661 )
+	png? ( media-libs/libpng )
+	pnm? ( media-libs/netpbm )
+	pulseaudio? ( media-sound/pulseaudio )
+	rar? (
+		|| (
+			app-arch/unrar
+			app-arch/rar
+		)
+	)
+	samba? ( net-fs/samba )
+	sdl? ( media-libs/libsdl )
+	speex? ( media-libs/speex )
+	theora? ( media-libs/libtheora )
+	truetype? ( ${FONT_RDEPS} )
+	vorbis? ( media-libs/libvorbis )
+	xanim? ( media-video/xanim )
+	xvid? ( media-libs/xvid )
+"
+ASM_DEP="dev-lang/yasm"
+DEPEND="${RDEPEND}
+	!!media-video/mplayer
+	dev-util/pkgconfig
+	dev-lang/python
+	sys-devel/gettext
+	X? (
+		x11-proto/videoproto
+		x11-proto/xf86vidmodeproto
+		dga? ( x11-proto/xf86dgaproto )
+		dxr3? ( media-video/em8300-libraries )
+		xinerama? ( x11-proto/xineramaproto )
+		xscreensaver? ( x11-proto/scrnsaverproto )
+	)
+	amd64? ( ${ASM_DEP} )
+	doc? (
+		dev-libs/libxslt app-text/docbook-xml-dtd
+		app-text/docbook-xsl-stylesheets
+	)
+	x86? ( ${ASM_DEP} )
+	x86-fbsd? ( ${ASM_DEP} )
+"
+
+pkg_setup() {
+	elog
+	elog "This is a live ebuild which installs the latest from upstream's"
+	elog "git repository, and is unsupported by Gentoo."
+	elog "Everything but bugs in the ebuild itself will be ignored."
+	elog
+
+	if use cpudetection; then
+		ewarn
+		ewarn "You've enabled the cpudetection flag. This feature is"
+		ewarn "included mainly for people who want to use the same"
+		ewarn "binary on another system with a different CPU architecture."
+		ewarn "MPlayer will already detect your CPU settings by default at"
+		ewarn "buildtime; this flag is used for runtime detection."
+		ewarn "You won't need this turned on if you are only building"
+		ewarn "mplayer for this system. Also, if your compile fails, try"
+		ewarn "disabling this use flag."
+	fi
+
+	if use custom-cpuopts; then
+		ewarn
+		ewarn "You are using the custom-cpuopts flag which will"
+		ewarn "specifically allow you to enable / disable certain"
+		ewarn "CPU optimizations."
+		ewarn
+		ewarn "Most desktop users won't need this functionality, but it"
+		ewarn "is included for corner cases like cross-compiling and"
+		ewarn "certain profiles. If unsure, disable this flag and MPlayer"
+		ewarn "will automatically detect and use your available CPU"
+		ewarn "optimizations."
+		ewarn
+		ewarn "Using this flag means your build is unsupported, so"
+		ewarn "please make sure your CPU optimization use flags (3dnow"
+		ewarn "3dnowext mmx mmxext sse sse2 ssse3) are properly set."
+	fi
+
+	einfo "For various format support you need to enable the support on your ffmpeg package:"
+	einfo "    media-video/libav or media-video/ffmpeg"
+}
+
+src_unpack() {
+	git_src_unpack
+
+	if ! use truetype; then
+		unpack font-arial-iso-8859-1.tar.bz2 \
+			font-arial-iso-8859-2.tar.bz2 \
+			font-arial-cp1250.tar.bz2
+	fi
+}
+
+src_prepare() {
+	# fix path to bash executable in configure scripts
+	local bash_scripts="configure version.sh"
+	sed -i \
+		-e "1c\#!${EPREFIX}/bin/bash" \
+		${bash_scripts} || die
+
+	base_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+	local uses i
+
+	# set LINGUAS
+	[[ -n $LINGUAS ]] && LINGUAS="${LINGUAS/da/dk}"
+
+	# mplayer ebuild uses "use foo || --disable-foo" to forcibly disable
+	# compilation in almost every situation. The reason for this is
+	# because if --enable is used, it will force the build of that option,
+	# regardless of whether the dependency is available or not.
+
+	###################
+	#Optional features#
+	###################
+	# disable svga since we don't want it
+	# disable arts since we don't have kde3
+	# disable tremor, it needs libvorbisidec and is for FPU-less systems only
+	myconf+="
+		--disable-svga
+		--disable-arts
+		--disable-kai
+		--disable-tremor
+		$(use_enable network networking)
+		$(use_enable joystick)
+	"
+	uses="ass bl bluray enca ftp rtc" # nemesi <- not working with in-tree ebuild
+	myconf+=" --disable-nemesi" # nemesi automagic disable
+	for i in ${uses}; do
+		use ${i} || myconf+=" --disable-${i}"
+	done
+	use bidi || myconf+=" --disable-fribidi"
+	use ipv6 || myconf+=" --disable-inet6"
+	use nut || myconf+=" --disable-libnut"
+	use rar || myconf+=" --disable-unrarexec"
+	use samba || myconf+=" --disable-smb"
+	if ! use lirc; then
+		myconf+="
+			--disable-lirc
+			--disable-lircc
+			--disable-apple-ir
+		"
+	fi
+
+	# libcdio support: prefer libcdio over cdparanoia
+	# don't check for cddb w/cdio
+	if use cdio; then
+		myconf+=" --disable-cdparanoia"
+	else
+		myconf+=" --disable-libcdio"
+		use cdparanoia || myconf+=" --disable-cdparanoia"
+		use cddb || myconf+=" --disable-cddb"
+	fi
+
+	################################
+	# DVD read, navigation support #
+	################################
+	#
+	# dvdread - accessing a DVD
+	# dvdnav - navigation of menus
+	#
+	# use external libdvdcss, dvdread and dvdnav
+	myconf+=" --disable-dvdread-internal --disable-libdvdcss-internal"
+	if use dvd; then
+		use dvdnav || myconf+=" --disable-dvdnav"
+	else
+		myconf+="
+			--disable-dvdnav
+			--disable-dvdread
+		"
+	fi
+
+	#############
+	# Subtitles #
+	#############
+	# SRT/ASS/SSA (subtitles) requires freetype support
+	# freetype support requires iconv
+	# iconv optionally can use unicode
+	if ! use ass && ! use truetype; then
+		myconf+=" --disable-freetype"
+		if ! use iconv; then
+			myconf+="
+				--disable-iconv
+				--charset=noconv
+			"
+		fi
+	fi
+	use iconv && use unicode && myconf+=" --charset=UTF-8"
+
+	#####################################
+	# DVB / Video4Linux / Radio support #
+	#####################################
+	myconf+=" --disable-tv-bsdbt848"
+	# broken upstream, won't work with recent kernels
+	myconf+=" --disable-ivtv"
+	if { use dvb || use v4l || use v4l2 || use pvr || use radio; }; then
+		use dvb || myconf+=" --disable-dvb"
+		use pvr || myconf+=" --disable-pvr"
+		use v4l || myconf+=" --disable-tv-v4l1"
+		use v4l2 || myconf+=" --disable-tv-v4l2"
+		if use radio && { use dvb || use v4l || use v4l2; }; then
+			myconf+="
+				--enable-radio
+				--disable-radio-capture
+			"
+		else
+			myconf+="
+				--disable-radio-v4l2
+				--disable-radio-bsdbt848
+			"
+		fi
+	else
+		myconf+="
+			--disable-tv
+			--disable-tv-v4l1
+			--disable-tv-v4l2
+			--disable-radio
+			--disable-radio-v4l2
+			--disable-radio-bsdbt848
+			--disable-dvb
+			--disable-v4l2
+			--disable-pvr"
+	fi
+
+	##########
+	# Codecs #
+	##########
+	myconf+=" --disable-musepack" # deprecated, libavcodec Musepack decoder is preferred
+	use dts || myconf+=" --disable-libdca"
+	use mp3 || myconf+=" --disable-mpg123"
+	uses="a52 bs2b dv vorbis"
+	for i in ${uses}; do
+		use ${i} || myconf+=" --disable-lib${i}"
+	done
+	uses="faad gif jpeg live mad mng png pnm speex tga theora xanim xvid"
+	for i in ${uses}; do
+		use ${i} || myconf+=" --disable-${i}"
+	done
+
+	#################
+	# Binary codecs #
+	#################
+	# bug 213836
+	if ! use x86 || ! use win32codecs; then
+		use quicktime || myconf+=" --disable-qtx"
+	fi
+
+	######################
+	# RealPlayer support #
+	######################
+	# Realplayer support shows up in four places:
+	# - libavcodec (internal)
+	# - win32codecs
+	# - realcodecs (win32codecs libs)
+	# - realcodecs (realplayer libs)
+
+	# internal
+	use real || myconf+=" --disable-real"
+
+	# Real binary codec support only available on x86, amd64
+	if use real; then
+		use x86 && myconf+=" --codecsdir=/opt/RealPlayer/codecs"
+		use amd64 && myconf+=" --codecsdir=/usr/$(get_libdir)/codecs"
+	fi
+	myconf+=" $(use_enable win32codecs win32dll)"
+
+	################
+	# Video Output #
+	################
+	uses="directfb md5sum sdl"
+	for i in ${uses}; do
+		use ${i} || myconf+=" --disable-${i}"
+	done
+	use aalib || myconf+=" --disable-aa"
+	use fbcon || myconf+=" --disable-fbdev"
+	use fbcon && use video_cards_s3virge && myconf+=" --enable-s3fb"
+	use libcaca || myconf+=" --disable-caca"
+
+	if ! use kernel_linux || ! use video_cards_mga; then
+		 myconf+=" --disable-mga --disable-xmga"
+	fi
+
+	if use video_cards_tdfx; then
+		myconf+="
+			$(use_enable video_cards_tdfx tdfxvid)
+			$(use_enable fbcon tdfxfb)
+		"
+	else
+		myconf+="
+			--disable-3dfx
+			--disable-tdfxvid
+			--disable-tdfxfb
+		"
+	fi
+
+	# sun card, disable by default, see bug #258729
+	myconf+=" --disable-xvr100"
+
+	################
+	# Audio Output #
+	################
+	uses="alsa esd jack ladspa nas"
+	for i in ${uses}; do
+		use ${i} || myconf+=" --disable-${i}"
+	done
+	#use openal && myconf+=" --enable-openal" # build fails
+	use pulseaudio || myconf+=" --disable-pulse"
+	if ! use radio; then
+		use oss || myconf+=" --disable-ossaudio"
+	fi
+
+	####################
+	# Advanced Options #
+	####################
+	# Platform specific flags, hardcoded on amd64 (see below)
+	use cpudetection && myconf+=" --enable-runtime-cpudetection"
+
+	# Turning off CPU optimizations usually will break the build.
+	# However, this use flag, if enabled, will allow users to completely
+	# specify which ones to use. If disabled, mplayer will automatically
+	# enable all CPU optimizations that the host build supports.
+	if use custom-cpuopts; then
+		uses="3dnow 3dnowext altivec mmx mmxext shm sse sse2 ssse3"
+		for i in ${uses}; do
+			myconf+=" $(use_enable ${i})"
+		done
+	fi
+
+	use debug && myconf+=" --enable-debug=3"
+
+	if use x86 && gcc-specs-pie; then
+		filter-flags -fPIC -fPIE
+		append-ldflags -nopie
+	fi
+
+	is-flag -O? || append-flags -O2
+
+	# workaround bug, x86 just has too few registers, see c.f.
+	# http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=402950#44
+	# and 32-bits OSX, bug 329861
+	if [[ ${CHOST} == i?86-* ]] ; then
+		use debug || append-flags -fomit-frame-pointer
+	fi
+
+	###########################
+	# X enabled configuration #
+	###########################
+	if use X; then
+		uses="dxr3 ggi xinerama"
+		for i in ${uses}; do
+			use ${i} || myconf+=" --disable-${i}"
+		done
+		use dga || myconf+=" --disable-dga1 --disable-dga2"
+		use opengl || myconf+=" --disable-gl"
+		use osdmenu && myconf+=" --enable-menu"
+		use vdpau || myconf+=" --disable-vdpau"
+		use video_cards_vesa || myconf+=" --disable-vesa"
+		use xscreensaver || myconf+=" --disable-xss"
+
+		if use xv; then
+			if use xvmc; then
+				myconf+=" --enable-xvmc --with-xvmclib=XvMCW"
+			else
+				myconf+=" --disable-xvmc"
+			fi
+		else
+			myconf+="
+				--disable-xv
+				--disable-xvmc
+			"
+			use xvmc && elog "Disabling xvmc because it requires \"xv\" useflag enabled."
+		fi
+	else
+		myconf+="
+			--disable-dga1
+			--disable-dga2
+			--disable-dxr3
+			--disable-ggi
+			--disable-gl
+			--disable-vdpau
+			--disable-xinerama
+			--disable-xss
+			--disable-xv
+			--disable-xvmc
+			--disable-x11
+		"
+		uses="dga dxr3 ggi opengl osdmenu vdpau xinerama xscreensaver xv"
+		for i in ${uses}; do
+			use ${i} && elog "Useflag \"${i}\" require \"X\" useflag enabled to work."
+		done
+	fi
+
+	############################
+	# OSX (aqua) configuration #
+	############################
+	if use aqua; then
+		myconf+="
+			--enable-macosx-finder
+			--enable-macosx-bundle
+		"
+	fi
+
+	./configure \
+		--cc=$(tc-getCC) \
+		--host-cc=$(tc-getBUILD_CC) \
+		--prefix="${EPREFIX}"/usr \
+		--bindir="${EPREFIX}"/usr/bin \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--confdir="${EPREFIX}"/etc/mplayer \
+		--datadir="${EPREFIX}"/usr/share/mplayer \
+		--mandir="${EPREFIX}"/usr/share/man \
+		--localedir="${EPREFIX}"/usr/share/locale \
+		--enable-translation \
+		${myconf} || die
+}
+
+src_compile() {
+	base_src_compile
+	# Build only user-requested docs if they're available.
+	if use doc ; then
+		# select available languages from $LINGUAS
+		LINGUAS=${LINGUAS/zh/zh_CN}
+		local ALLOWED_LINGUAS="cs de en es fr hu it pl ru zh_CN"
+		local BUILT_DOCS=""
+		for i in ${LINGUAS} ; do
+			has ${i} ${ALLOWED_LINGUAS} && BUILT_DOCS+=" ${i}"
+		done
+		if [[ -z $BUILT_DOCS ]]; then
+			emake -j1 -C DOCS/xml html-chunked
+		else
+			for i in ${BUILT_DOCS}; do
+				emake -j1 -C DOCS/xml html-chunked-${i}
+			done
+		fi
+	fi
+}
+
+src_install() {
+	local i
+
+	emake \
+		DESTDIR="${ED}" \
+		INSTALLSTRIP="" \
+		install
+
+	dodoc AUTHORS Copyright README etc/codecs.conf
+
+	docinto tech/
+	dodoc DOCS/tech/{*.txt,mpsub.sub,playtree}
+	docinto TOOLS/
+	dodoc -r TOOLS
+	if use real; then
+		docinto tech/realcodecs/
+		dodoc DOCS/tech/realcodecs/*
+	fi
+
+	if use doc; then
+		docinto html/
+		dohtml -r "${S}"/DOCS/HTML/*
+	fi
+
+	if ! use ass && ! use truetype; then
+		dodir /usr/share/mplayer/fonts
+		# Do this generic, as the mplayer people like to change the structure
+		# of their zips ...
+		for i in $(find "${WORKDIR}/" -type d -name 'font-arial-*'); do
+			cp -pPR "${i}" "${ED}/usr/share/mplayer/fonts"
+		done
+		# Fix the font symlink ...
+		rm -rf "${ED}/usr/share/mplayer/font"
+		dosym fonts/font-arial-14-iso-8859-1 /usr/share/mplayer/font
+	fi
+
+	insinto /etc/mplayer
+	newins "${S}/etc/example.conf" mplayer.conf
+	cat >> "${ED}/etc/mplayer/mplayer.conf" << _EOF_
+# Config options can be section specific, global
+# options should go in the default section
+[default]
+_EOF_
+	doins "${S}/etc/input.conf"
+	use osdmenu && doins "${S}/etc/menu.conf"
+
+	# set unrar path when required
+	if use rar; then
+		cat >> "${ED}/etc/mplayer/mplayer.conf" << _EOF_
+unrarexec=${EPREFIX}/usr/bin/unrar
+_EOF_
+	fi
+	dosym ../../../etc/mplayer/mplayer.conf /usr/share/mplayer/mplayer.conf
+
+	newbin "${S}/TOOLS/midentify.sh" midentify
+}