Fix from upstream for rtc/hwclock handling #179780 and fix for losetup -P with loop-aes #201981.

(Portage version: 2.1.4_rc9)

1 files changed, 89 insertions, 0 deletions

diff --git a/sys-apps/util-linux/util-linux-2.13-r3.ebuild b/sys-apps/util-linux/util-linux-2.13-r3.ebuild
new file mode 100644
index 000000000000..ae458c69ed0a
--- /dev/null
+++ b/sys-apps/util-linux/util-linux-2.13-r3.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-2.13-r3.ebuild,v 1.1 2007/12/14 03:18:57 vapier Exp $
+
+EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/util-linux-ng/util-linux-ng.git"
+inherit eutils
+[[ ${PV} == "9999" ]] && inherit git
+
+MY_PV=${PV/_/-}
+MY_P=${PN}-ng-${MY_PV}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="Various useful Linux utilities"
+HOMEPAGE="http://www.kernel.org/pub/linux/utils/util-linux-ng/"
+if [[ ${PV} == "9999" ]] ; then
+	SRC_URI=""
+else
+	SRC_URI="http://www.kernel.org/pub/linux/utils/util-linux-ng/v${PV:0:4}/${MY_P}.tar.bz2
+		crypt? ( http://loop-aes.sourceforge.net/updates/${MY_P}-1.diff.bz2 )"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="crypt nls old-linux selinux"
+
+RDEPEND="!sys-process/schedutils
+	!sys-apps/setarch
+	>=sys-libs/ncurses-5.2-r2
+	>=sys-fs/e2fsprogs-1.34
+	selinux? ( sys-libs/libselinux )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	virtual/os-headers"
+
+src_unpack() {
+	if [[ ${PV} == "9999" ]] ; then
+		git_src_unpack
+		cd "${S}"
+		./autogen.sh || die
+	else
+		unpack ${A}
+		cd "${S}"
+		epatch "${FILESDIR}"/${P}-locale.patch #191111
+		epatch "${FILESDIR}"/${P}-ioprio-syscalls.patch #190613
+		epatch "${FILESDIR}"/${P}-setuid-checks.patch
+		epatch "${FILESDIR}"/${P}-script-SIGWINCH.patch #191452
+		epatch "${FILESDIR}"/${P}-hwclock-rtc.patch #179780
+		use crypt && epatch "${WORKDIR}"/${MY_P}-1.diff "${FILESDIR}"/${P}-losetup-P.patch #201981
+		sed -i '/#include <asm\/page.h>/d' mount/swapon.c || die
+	fi
+}
+
+src_compile() {
+	export localedir="/usr/share/locale" #190895
+	econf \
+		--with-fsprobe=blkid \
+		$(use_enable nls) \
+		--enable-agetty \
+		--enable-cramfs \
+		$(use_enable old-linux elvtune) \
+		--disable-init \
+		--disable-kill \
+		--disable-last \
+		--disable-mesg \
+		--enable-partx \
+		--enable-raw \
+		--enable-rdev \
+		--enable-rename \
+		--disable-reset \
+		--disable-login-utils \
+		--enable-schedutils \
+		--disable-wall \
+		--enable-write \
+		--without-pam \
+		$(use_with selinux) \
+		|| die "configure failed"
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "install failed"
+	dodoc AUTHORS NEWS README* TODO docs/*
+
+	if use crypt ; then
+		newinitd "${FILESDIR}"/crypto-loop.initd crypto-loop || die
+		newconfd "${FILESDIR}"/crypto-loop.confd crypto-loop || die
+	fi
+}